> < ^ Date: Mon, 17 Sep 2001 19:06:10 +0200
> < ^ From: Thomas Breuer <Thomas.Breuer@Math.RWTH-Aachen.DE >
< ^ Subject: Re: Transrate characters

Dear GAP Forum,

Katsushi Waki wrote

I want to know how to translate characters from quotinet group.
I mean that let G is a finite group and N is a normal subgroup of G.
I want to use characters of G/N as characters of G.

This is described in the section "Restricted and Induced Class Functions"
in the GAP Reference Manual,
which states that inflating characters of a factor group can be done
using `RestrictedClassFunction' or `RestrictedClassFunctions'.

The connection between the group \$G\$ and its factor group \$F\$ must be made
explicit either by a homomorphism from \$G\$ to \$F\$ or by the fact that
the factor fusion is stored on the character table of \$G\$.

Here is an example.

```gap> g:= SymmetricGroup( 4 );
Sym( [ 1 .. 4 ] )
gap> n:= DerivedSubgroup( g );;
gap> hom:= NaturalHomomorphismByNormalSubgroup( g, n );
[ (1,2,3,4), (1,2) ] -> [ f1, f1 ]
gap> f:= Image( hom );
Group([ f1 ])
gap> firr:= Irr( f );
[ Character( CharacterTable( Group([ f1 ]) ), [ 1, 1 ] ),
Character( CharacterTable( Group([ f1 ]) ), [ 1, -1 ] ) ]
gap> RestrictedClassFunctions( firr, hom );
[ Character( CharacterTable( Sym( [ 1 .. 4 ] ) ), [ 1, 1, 1, 1, 1 ] ),
Character( CharacterTable( Sym( [ 1 .. 4 ] ) ), [ 1, -1, 1, 1, -1 ] ) ]
```

And here is the variant with the stored factor fusion.
First we compute and store it ...

```gap> fus:= FusionConjugacyClasses( hom );
[ 1, 2, 1, 1, 2 ]
gap> gtbl:= CharacterTable( g );
CharacterTable( Sym( [ 1 .. 4 ] ) )
gap> ftbl:= CharacterTable( f );
CharacterTable( Group([ f1 ]) )
gap> StoreFusion( gtbl, fus, ftbl );
```

... and now we can inflate characters also as follows.

```gap> RestrictedClassFunctions( firr, gtbl );
[ Character( CharacterTable( Sym( [ 1 .. 4 ] ) ), [ 1, 1, 1, 1, 1 ] ),
Character( CharacterTable( Sym( [ 1 .. 4 ] ) ), [ 1, -1, 1, 1, -1 ] ) ]
```

I hope this helps.

Kind regards,
Thomas

> < [top]