7.73 ConjugacyClassesSubgroups

`ConjugacyClassesSubgroups( G )`

`ConjugacyClassesSubgroups` returns a list of all conjugacy classes of subgroups of the group G. The elements in the list returned are conjugacy class domains as created by `ConjugacyClassSubgroups` (see ConjugacyClassSubgroups). Because conjugacy classes are domains, all set theoretic functions can be applied to them (see Domains).

In fact, `ConjugacyClassesSubgroups` computes much more than it returns, for it calls (indirectly via the function `G.operations.ConjugacyClassesSubgroups( G )`) the `Lattice` command (see Lattice), constructs the whole subgroup lattice of G, stores it in the record component `G.lattice`, and finally returns the list `G.lattice.classes`. This means, in particular, that it will fail if G is non-solvable and its maximal perfect subgroup is not in the built-in catalogue of perfect groups (see the description of the `Lattice` command Lattice for details).

```    gap> # Conjugacy classes of subgroups of S4
gap> s4 := Group( (1,2,3,4), (1,2) );;
gap> s4.name := "s4";;
gap> cl := ConjugacyClassesSubgroups( s4 );
[ ConjugacyClassSubgroups( s4, Subgroup( s4, [  ] ) ),
ConjugacyClassSubgroups( s4, Subgroup( s4, [ (1,2)(3,4) ] ) ),
ConjugacyClassSubgroups( s4, Subgroup( s4, [ (3,4) ] ) ),
ConjugacyClassSubgroups( s4, Subgroup( s4, [ (2,3,4) ] ) ),
ConjugacyClassSubgroups( s4, Subgroup( s4, [ (1,2)(3,4), (1,3)(2,4)
] ) ), ConjugacyClassSubgroups( s4, Subgroup( s4,
[ (3,4), (1,2) ] ) ), ConjugacyClassSubgroups( s4, Subgroup( s4,
[ (1,2)(3,4), (1,4,2,3) ] ) ),
ConjugacyClassSubgroups( s4, Subgroup( s4, [ (2,3,4), (3,4) ] ) ),
ConjugacyClassSubgroups( s4, Subgroup( s4,
[ (3,4), (1,2), (1,3)(2,4) ] ) ),
ConjugacyClassSubgroups( s4, Subgroup( s4,
[ (1,2)(3,4), (1,3)(2,4), (2,3,4) ] ) ),
ConjugacyClassSubgroups( s4, s4 ) ] ```

Each entry of the resulting list is a domain. As an example, let us take the seventh class in the above list of conjugacy classes of S_4.

```    gap> # Conjugacy classes of subgroups of S4 (continued)
gap> class7 := cl[7];;
gap> # Print the class representative subgroup.
gap> rep7 := Representative( class7 );
Subgroup( s4, [ (1,2)(3,4), (1,4,2,3) ] )
gap> # Print the order of the class representative subgroup.
gap> Size( rep7 );
4
gap> # Print the number of conjugates.
gap> Size( class7 );
3 ```

GAP 3.4.4
April 1997