42.9 Images

`Images( map, elm )`

In this form `Images` returns the set of images of the element elm in the source of the mapping map under map. map may be a multi valued mapping.

```    gap> g := Group( (1,2,3,4), (2,4), (5,6,7) );;  g.name := "g";;
gap> p4 := MappingByFunction( g, g, x -> x^4 );
MappingByFunction( g, g, function ( x )
return x ^ 4;
end )
gap> i4 := InverseMapping( p4 );
InverseMapping( MappingByFunction( g, g, function ( x )
return x ^ 4;
end ) )
gap> IsMapping( i4 );
false    # 'i4' is multi valued
gap> Images( i4, () );
[ (), (2,4), (1,2)(3,4), (1,2,3,4), (1,3), (1,3)(2,4), (1,4,3,2),
(1,4)(2,3) ]
gap> p5 := MappingByFunction( g, g, x -> x^5 );
MappingByFunction( g, g, function ( x )
return x ^ 5;
end )
gap> i5 := InverseMapping( p5 );
InverseMapping( MappingByFunction( g, g, function ( x )
return x ^ 5;
end ) )
gap> Images( i5, () );
[ () ] ```

`Images( map, elms )`

In this form `Images` returns the set of images of the set of elements elms in the source of map under map. map may be a multi valued mapping. In any case `Images` returns a set of elements of the range of map, either as a proper set (see Sets) or as a domain (see Domains).

```    gap> Images( i4, [ (), (5,6,7) ] );
[ (), (5,6,7), (2,4), (2,4)(5,6,7), (1,2)(3,4), (1,2)(3,4)(5,6,7),
(1,2,3,4), (1,2,3,4)(5,6,7), (1,3), (1,3)(5,6,7), (1,3)(2,4),
(1,3)(2,4)(5,6,7), (1,4,3,2), (1,4,3,2)(5,6,7), (1,4)(2,3),
(1,4)(2,3)(5,6,7) ]
gap> Images( i5, [ (), (5,6,7) ] );
[ (), (5,7,6) ] ```

`Images` first checks in which form it is called.

In the first case it calls `map.operations.ImagesElm( map, elm )` and returns this value.

The default function called this way is `MappingOps.ImagesElm`, which just raises an error, since their is no default way to compute the images of an element under a mapping about which nothing is known. Look in the index under Images to see how images are computed for the various mappings.

In the second case it calls `map.operations.ImagesSet( map, elms )` and returns this value.

The default function called this way is `MappingOps.ImagesSet`, which returns the union of the images of all the elements in the set elms. Look in the index under Images to see for which mappings this function is overlaid.

GAP 3.4.4
April 1997