Previous About HAP: Aspherical presentations next

The 2-dimensional connected CW-space KP associated to a group presentation P = < x | r > is said to be aspherical if its second homotopy group is trivial. In this case the universal cover X  of KP is a contractible 2-dimensional CW-space admitting a free cellular action of the group G determined by the presentation. The cellular chain complex of X is thus a free ZG-resolution of Z.

A sufficient (but certainly not necessary) condition for KP to be aspherical is that it admits a non-positively curved metric which restrict to a Euclidean metric on each 2-cell. This sufficient condition can be expressed as a set of inequalities. The function IsAspherical() applies Polymake software to a subset of these inequalities to test whether KP is aspherical.

The following commands show that this asphericity test is inconclusive on the standard presentation

P=< x, y, z | xyx=yxy, yzy=zyz, zxz=xzx >

of the 4-string affine braid group.
gap> F:=FreeGroup(3);;x:=F.1;;y:=F.2;;z:=F.3;;
gap> rels:=[x*y*x*(y*x*y)^-1, y*z*y*(z*y*z)^-1, z*x*z*(x*z*x)^-1];;

gap> IsAspherical(F,rels);
Presentation is NOT piece-wise Euclidean non-positively curved.

fail
Asphericity is obviously a homotopy invariant. So we can continue to test the asphericity of KP by applying the above test to presentations P' of the affine braid group for which the associated space KP' is homotopy equivalent to KP.

One way to construct a suitable presentation P' is to add to the presentation P one generator a and one relation a=xy, and replace by a all occurences of xy in the relators. The resulting spaces KP and KP' are then in fact simple homotopy equivalent. Repeating this process with b=yz and c=zx yields the presentation

P' = <x,y,z,a,b,c, | a=xy, b=yz, c=zx, ax=ya, by=zb, cz=xc >

of the affine braid group.

The following commands show that KP' is aspherical, and hence that KP is also aspherical.
gap> F:=FreeGroup(6);;x:=F.1;;y:=F.2;;z:=F.3;;a:=F.4;;b:=F.5;;c:=F.6;;
gap> rels:=[a^-1*x*y, b^-1*y*z, c^-1*z*x, a*x*(y*a)^-1, b*y*(z*b)^-1, c*z*(x*c)^-1];;

gap> IsAspherical(F,rels);
Presentation is aspherical.

true
The 4-string affine braid group thus has integral homology Hn(G,Z)=0 for n>2. The following commands show that H1(G,Z)=Z and H2(G,Z)=Z.
gap> F:=FreeGroup(3);;x:=F.1;;y:=F.2;;z:=F.3;;
gap> rels:=[x*y*x*(y*x*y)^-1, y*z*y*(z*y*z)^-1, z*x*z*(x*z*x)^-1];;

gap> R:=ResolutionAsphericalPresentation(F,rels);;
gap> TR:=TensorWithIntegers(R);;
gap> Homology(TR,1);
[0]
gap> Homology(TR,2);
[0]
We should remark that the asphericity of the above presentation P can be derived from a lemma in  [K.J. Appel and P.E. Schupp, "Artin groups and infinite Coxeter groups", Invent. Math., 72 (1983), 201-220].
 Previous Page Contents Next page