Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 13 A B C Bib Ind

### 11 Affine semigroups

#### 11.1 Defining affine semigroups

An affine semigroup S is a finitely generated cancellative monoid that is reduced (no units other than 0) and is torsion-free (a s= b s implies a=b, with a,b∈ N and s∈ S). Up to isomorphisms any affine semigroup can be viewed as a finitely generated submonoid of N^k for some positive integer k. Thus affine semigroups are a natural generalization of numerical semigroups. The most common way to give an affine semigroup is by any of its systems of generators. As for numerical semigroups, any affine semigroup admits a unique minimal system of generators. A system of generators can be represented as a list of lists of nonnegative integers; all lists in the list having the same length (a matrix actually). If G is a subgroup of Z^k, then S=G∩ N^k is an affine semigroup (these semigroups are called full affine semigroups). As G can be represented by its defining equations (homogeneous and some of them possibly in congruences), we can represent S by the defining equations of G; indeed S is just the set of nonnegative solutions of this system of equations. We can represent the equations as a list of lists of integers, all with the same length. Every list is a row of the matrix of coefficients of the system of equations. For the equations in congruences, if we arrange them so that they are the first ones in the list, we provide the corresponding moduli in a list. So for instance, the equations x+y≡ 0mod 2, x-2y=0 will be represented as [[1,1],[1,-2]] and the moduli [2].

As happens with numerical semigroups, there are different ways to specify an affine semigroup S, namely, by means of a system of generators, a system of homogeneous linear Diophantine equations or a system of homogeneous linear Diophantine inequalities, just to mention some. In this section we describe functions that may be used to specify, in one of these ways, an affine semigroup in GAP.

##### 11.1-1 AffineSemigroupByGenerators
 ‣ AffineSemigroupByGenerators( List ) ( function )
 ‣ AffineSemigroup( String, List ) ( function )

List is a list of n-tuples of nonnegative integers, if the semigroup to be created is n-dimensional. The n-tuples may be given as a list or by a sequence of individual elements. The output is the affine semigroup spanned by List.

String does not need to be present. When it is present, it must be "generators" and List must be a list, not a sequence of individual elements.

gap> s1 := AffineSemigroupByGenerators([1,3],[7,2],[1,5]);
<Affine semigroup in 2 dimensional space, with 3 generators>
gap> s2 := AffineSemigroupByGenerators([[1,3],[7,2],[1,5]]);;
gap> s3 := AffineSemigroup("generators",[[1,3],[7,2],[1,5]]);;
gap> s4 := AffineSemigroup([1,3],[7,2],[1,5]);;
gap> s5 := AffineSemigroup([[1,3],[7,2],[1,5]]);;
gap> Length(Set([s1,s2,s3,s4,s5]));
1


##### 11.1-2 AffineSemigroupByEquations
 ‣ AffineSemigroupByEquations( List ) ( function )
 ‣ AffineSemigroup( String, List ) ( function )

List is a list with two components. The first represents a matrix with integer coefficients, say A=(a_ij), and so it is a list of lists of integers all with the same length. The second component is a list of positive integers, say d=(d_i), which may be empty. The list d must be of length less than or equal to the length of A (number of rows of A).

The output is the full semigroup of nonnegative integer solutions to the system of homogeneous equations
a_11x_1+⋯+a_1nx_n≡ 0mod d_1,

a_k1x_1+⋯+a_knx_n≡ 0mod d_k,
a_k+1 1x_1+⋯ +a_k+1 n=0,

a_m1x_1+⋯+a_mnx_n=0.

If d is empty, then there will be no equations in congruences.

As pointed at the beginning of the section, the equations x+y≡ 0mod 2, x-2y=0 will be represented as A equal to [[1,1],[1,-2]] and the moduli d equal to [2].

In the second form, String must be "equations".

gap> s1 := AffineSemigroupByEquations([[[-2,1]],[3]]);
<Affine semigroup>
gap> s2 := AffineSemigroup("equations",[[[1,1]],[3]]);
<Affine semigroup>
gap> s1=s2;
true


##### 11.1-3 AffineSemigroupByInequalities
 ‣ AffineSemigroupByInequalities( List ) ( function )
 ‣ AffineSemigroup( String, List ) ( function )

List is a list of lists (a matrix) of integers that represents a set of inequalities.

Returns the (normal) affine semigroup of nonegative integer solutions of the system of inequalities List× Xge 0.

In the second form, String must be "inequalities".

gap> a1:=AffineSemigroupByInequalities([[2,-1],[-1,3]]);
<Affine semigroup>
gap> a2:=AffineSemigroup("inequalities",[[2,-1],[-1,3]]);
<Affine semigroup>
gap> a1=a2;
true


##### 11.1-4 Generators
 ‣ Generators( S ) ( function )
 ‣ GeneratorsOfAffineSemigroup( S ) ( function )

S is an affine semigroup, the output is a system of generators.

gap> a:=AffineSemigroup([[1,0],[0,1],[1,1]]);
<Affine semigroup in 2 dimensional space, with 3 generators>
gap> Generators(a);
[ [ 0, 1 ], [ 1, 0 ], [ 1, 1 ] ]


##### 11.1-5 MinimalGenerators
 ‣ MinimalGenerators( S ) ( function )
 ‣ MinimalGeneratingSystem( S ) ( function )

S is an affine semigroup, the output is its system of minimal generators.

gap> a:=AffineSemigroup([[1,0],[0,1],[1,1]]);
<Affine semigroup in 2 dimensional space, with 3 generators>
gap> MinimalGenerators(a);
[ [ 0, 1 ], [ 1, 0 ] ]


##### 11.1-6 AsAffineSemigroup
 ‣ AsAffineSemigroup( S ) ( function )

S is a numerical semigroup, the output is S regarded as an affine semigroup.

gap> s:=NumericalSemigroup(1310,1411,1546,1601);
<Numerical semigroup with 4 generators>
gap> MinimalPresentationOfNumericalSemigroup(s);;time;
2960
gap> a:=AsAffineSemigroup(s);
<Affine semigroup in 1 dimensional space, with 4 generators>
gap> GeneratorsOfAffineSemigroup(a);
[ [ 1310 ], [ 1411 ], [ 1546 ], [ 1601 ] ]
gap> MinimalPresentationOfAffineSemigroup(a);;time;
237972


If we use the package SingularInterface, the speed up is considerable.

gap> NumSgpsUseSingularInterface();
...
gap> MinimalPresentationOfAffineSemigroup(a);;time;
32


##### 11.1-7 IsAffineSemigroup
 ‣ IsAffineSemigroup( AS ) ( attribute )
 ‣ IsAffineSemigroupByGenerators( AS ) ( attribute )
 ‣ IsAffineSemigroupByEquations( AS ) ( attribute )
 ‣ IsAffineSemigroupByInequalities( AS ) ( attribute )

AS is an affine semigroup and these attributes are available (their names should be self explanatory). They reflect what is currently known about the semigroup.

gap> a1:=AffineSemigroup([[3,0],[2,1],[1,2],[0,3]]);
<Affine semigroup in 2 dimensional space, with 4 generators>
gap> IsAffineSemigroupByEquations(a1);
false
gap> IsAffineSemigroupByGenerators(a1);
true


##### 11.1-8 BelongsToAffineSemigroup
 ‣ BelongsToAffineSemigroup( v, a ) ( function )
 ‣ \in( v, a ) ( operation )

v is a list of nonnegative integers and a an affine semigroup. Returns true if the vector is in the semigroup, and false otherwise.

If the semigroup is full and its equations are known (either because the semigroup was defined by equations, or because the user has called IsFullAffineSemgiroup(a) and the output was true), then membership is performed by evaluating v in the equations. The same holds for normal semigroups and its defining inequalities.

v in a can be used for short.

gap> a:=AffineSemigroup([[2,0],[0,2],[1,1]]);;
gap> BelongsToAffineSemigroup([5,5],a);
true
gap> BelongsToAffineSemigroup([1,2],a);
false
gap> [5,5] in a;
true
gap> [1,2] in a;
false


##### 11.1-9 IsFull
 ‣ IsFull( S ) ( property )
 ‣ IsFullAffineSemigroup( S ) ( property )

s is an affine semigroup.

Returns true if the semigroup is full, false otherwise. The semigroup is full if whenever a,b∈ S and b-a∈ N^k, then a-b∈ S, where k is the dimension of S.

If the semigroup is full, then its equations are stored in the semigroup for further use.

gap> a:=AffineSemigroup("equations",[[[1,1,1],[0,0,2]],[2,2]]);;
gap> IsFullAffineSemigroup(a);
true


##### 11.1-10 HilbertBasisOfSystemOfHomogeneousEquations
 ‣ HilbertBasisOfSystemOfHomogeneousEquations( ls, m ) ( operation )

ls is a list of lists of integers and m a list of integers. The elements of ls represent the rows of a matrix A. The output is a minimal generating system (Hilbert basis) of the set of nonnegative integer solutions of the system Ax=0 where the k first equations are in the congruences modulo m[i], with k the length of m.

If the package NormalizInterface has not been loaded, then Contejean-Devie algorithm is used [CD94] instead (if this is the case, congruences are treated as in [RGS98]).

gap> HilbertBasisOfSystemOfHomogeneousEquations([[1,0,1],[0,1,-1]],[2]);
[ [ 0, 2, 2 ], [ 1, 1, 1 ], [ 2, 0, 0 ] ]


If C is a pointed cone (a cone in Q^k not containing lines and 0∈ C), then S=C∩ N^k is an affine semigroup (known as normal affine semigroup). So another way to give an affine semigroup is by a set of homogeneous inequalities, and we can represent these inequalities by its coefficients. If we put them in a matrix S can be defined as the set of nonnegative integer solutions to Ax ge 0.

##### 11.1-11 HilbertBasisOfSystemOfHomogeneousInequalities
 ‣ HilbertBasisOfSystemOfHomogeneousInequalities( ls ) ( operation )

ls is a list of lists of integers. The elements of ls represent the rows of a matrix A. The output is a minimal generating system (Hilbert basis) of the set of nonnegative integer solutions to Axge 0.

If the package NormalizInterface has not been loaded, then Contejean-Devie algorithm is used [CD94] instead (the use of slack variables is described in [CAGGB02]).

gap> HilbertBasisOfSystemOfHomogeneousInequalities([[2,-3],[0,1]]);
[ [ 1, 0 ], [ 2, 1 ], [ 3, 2 ] ]


##### 11.1-12 EquationsOfGroupGeneratedBy
 ‣ EquationsOfGroupGeneratedBy( M ) ( function )

M is a matrix of integers. The output is a pair [A,m] that represents the set of defining equations of the group spanned by the rows of M: Ax=0∈ Z_n_1× ⋯ × Z_n_t× Z^k, with m=[n_1,...,n_t].

gap> EquationsOfGroupGeneratedBy([[1,2,0],[2,-2,2]]);
[ [ [ 0, 0, -1 ], [ -2, 1, 3 ] ], [ 2 ] ]


##### 11.1-13 BasisOfGroupGivenByEquations
 ‣ BasisOfGroupGivenByEquations( A, m ) ( function )

A is a matrix of integers and m is a list of positive integers. The output is a basis for the group with defining equations Ax=0∈ Z_n_1× ⋯ × Z_n_t× Z^k, with m=[n_1,...,n_t].

gap> BasisOfGroupGivenByEquations([[0,0,1],[2,-1,-3]],[2]);
[ [ -1, -2, 0 ], [ -2, 2, -2 ] ]


#### 11.2 Gluings of affine semigroups

Let S_1 and S_2 be two affine semigroups with the same dimension generated by A_1 and A_2, respectively. We say that the affine semigroup S generated by the union of A_1 and A_2 is a gluing of S_1 and S_2 if G(S_1)∩ G(S_2)=d Z (G(⋅) stands for group spanned by) for some d∈ S_1∩ S_2.

The algorithm used is explained in [RGS99a].

##### 11.2-1 GluingOfAffineSemigroups
 ‣ GluingOfAffineSemigroups( a1, a2 ) ( function )

a1, a2 are affine semigroups. Determines if they can be glued, and if so, returns the gluing. Otherwise it returns fail.

gap> a1:=AffineSemigroup([[2,0],[0,2]]);
<Affine semigroup in 2 dimensional space, with 2 generators>
gap> a2:=AffineSemigroup([[1,1]]);
<Affine semigroup in 2 dimensional space, with 1 generators>
gap> GluingOfAffineSemigroups(a1,a2);
<Affine semigroup in 2 dimensional space, with 3 generators>
gap> Generators(last);
[ [ 0, 2 ], [ 1, 1 ], [ 2, 0 ] ]


#### 11.3 Presentations of affine semigroups

A minimal presentation of an affine semigroup is defined analogously as for numerical semigroups. The user might take into account that generators are stored in a set, and thus might be arranged in a different way to the initial input.

##### 11.3-1 GeneratorsOfKernelCongruence
 ‣ GeneratorsOfKernelCongruence( M ) ( operation )

M is matrix with nonnegative integer coefficients. The output is a system of generators of the congruence {(x,y)∣ xM=yM}.

The main difference with MinimalPresentationOfAffineSemigroup is that the matrix M can have repeated columns and these are not treated as a set.

##### 11.3-2 CanonicalBasisOfKernelCongruence
 ‣ CanonicalBasisOfKernelCongruence( M, Ord ) ( operation )

M is matrix with nonnegative integer coefficients, Ord a term ordering. The output is a canonical bases of the congruence {(x,y)∣ xM=yM} (see [RGS99b]). This corresponds with the exponents of the Gröbner basis of the kernel ideal of the morphism x_i↦ Y^m_i, with m_i the ith row of M.

Accepted term orderings are lexicographic (MonomialLexOrdering()), graded lexicographic (MonomialGrlexOrdering()) and reversed graded lexicographic (MonomialGrevlexOrdering()).

gap> M:=[[3],[5],[7]];;
gap> CanonicalBasisOfKernelCongruence(M,MonomialLexOrdering());
[ [ [ 0, 7, 0 ], [ 0, 0, 5 ] ], [ [ 1, 0, 1 ], [ 0, 2, 0 ] ],
[ [ 1, 5, 0 ], [ 0, 0, 4 ] ], [ [ 2, 3, 0 ], [ 0, 0, 3 ] ],
[ [ 3, 1, 0 ], [ 0, 0, 2 ] ], [ [ 4, 0, 0 ], [ 0, 1, 1 ] ] ]
gap> CanonicalBasisOfKernelCongruence(M,MonomialGrlexOrdering());
[ [ [ 0, 7, 0 ], [ 0, 0, 5 ] ], [ [ 1, 0, 1 ], [ 0, 2, 0 ] ],
[ [ 1, 5, 0 ], [ 0, 0, 4 ] ], [ [ 2, 3, 0 ], [ 0, 0, 3 ] ],
[ [ 3, 1, 0 ], [ 0, 0, 2 ] ], [ [ 4, 0, 0 ], [ 0, 1, 1 ] ] ]
gap> CanonicalBasisOfKernelCongruence(M,MonomialGrevlexOrdering());
[ [ [ 0, 2, 0 ], [ 1, 0, 1 ] ], [ [ 3, 1, 0 ], [ 0, 0, 2 ] ],
[ [ 4, 0, 0 ], [ 0, 1, 1 ] ] ]


##### 11.3-3 GraverBasis
 ‣ GraverBasis( M ) ( operation )

M is matrix with integer coefficients. The output is a Graver basis for M.

gap> gr:=GraverBasis([[3,5,7]]);
[ [ -7, 0, 3 ], [ -5, 3, 0 ], [ -4, 1, 1 ], [ -3, -1, 2 ], [ -2, -3, 3 ],
[ -1, -5, 4 ], [ -1, 2, -1 ], [ 0, -7, 5 ], [ 0, 7, -5 ], [ 1, -2, 1 ],
[ 1, 5, -4 ], [ 2, 3, -3 ], [ 3, 1, -2 ], [ 4, -1, -1 ], [ 5, -3, 0 ],
[ 7, 0, -3 ] ]


##### 11.3-4 MinimalPresentationOfAffineSemigroup
 ‣ MinimalPresentationOfAffineSemigroup( a ) ( operation )
 ‣ MinimalPresentation( a ) ( operation )

a is an affine semigroup. The output is a minimal presentation for a.

There are four methods implemented for this function, depending on the packages loaded. All of them use elimination, and Herzog's correspondence, computing the kernel of a ring homomorphism ([Her70]). The fastest procedure is achieved when SingularInterface is loaded, followed by Singular. The procedure that does not use external packages uses internal GAP Gröbner basis computations and thus it is slower. Also in this case, from the Gröbner basis, a minimal set of generating binomials must be refined, and for this Rclasses are used (if NormalizInterface is loaded, then the factorizations are faster). The 4ti2 implementation uses 4ti2 internal Gröbner bases and factorizations are done via zsolve.

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> MinimalPresentationOfAffineSemigroup(a);
[ [ [ 1, 0, 1 ], [ 0, 2, 0 ] ] ]
gap> GeneratorsOfAffineSemigroup(a);
[ [ 0, 2 ], [ 1, 1 ], [ 2, 0 ] ]


##### 11.3-5 BettiElementsOfAffineSemigroup
 ‣ BettiElementsOfAffineSemigroup( a ) ( operation )
 ‣ BettiElements( a ) ( operation )

a is an affine semigroup. The output is the set of Betti elements of a (defined as for numerical semigroups).

This function relies on the computation of a minimal presentation.

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> BettiElementsOfAffineSemigroup(a);
[ [ 2, 2 ] ]


 ‣ ShadedSetOfElementInAffineSemigroup( v, a ) ( function )

a is an affine semigroup and v is an element in a. This is a translation to affine semigroups of ShadedSetOfElementInNumericalSemigroup (4.1-5).

##### 11.3-7 IsGeneric
 ‣ IsGeneric( a ) ( property )
 ‣ IsGenericAffineSemigroup( a ) ( property )

a is an affine semigroup.

The same as IsGenericNumericalSemigroup (4.2-2) but for affine semigroups.

##### 11.3-8 IsUniquelyPresentedAffineSemigroup
 ‣ IsUniquelyPresentedAffineSemigroup( a ) ( property )

a is an affine semigroup.

The same as IsUniquelyPresentedNumericalSemigroup (4.2-1) but for affine semigroups.

##### 11.3-9 PrimitiveElementsOfAffineSemigroup
 ‣ PrimitiveElementsOfAffineSemigroup( a ) ( operation )

a is an affine semigroup. The output is the set of primitive elements of a (defined as for numerical semigroups).

This function has three implementations (methods), one using Graver basis via the Lawrence lifting of a and the other (much faster) using NormalizInterface. Also a 4ti2 version using its Graver basis computation is provided.

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> PrimitiveElementsOfAffineSemigroup(a);
[ [ 0, 2 ], [ 1, 1 ], [ 2, 0 ], [ 2, 2 ] ]


#### 11.4 Factorizations in affine semigroups

The invariants presented here are defined as for numerical semigroups.

As with presentations, the user should take into account that generators are stored in a set, and thus might be arranged in a different way to the initial input.

##### 11.4-1 FactorizationsVectorWRTList
 ‣ FactorizationsVectorWRTList( v, ls ) ( operation )

v is a list of nonnegative integers and ls is a list of lists of nonnegative integers. The output is set of factorizations of v in terms of the elements of ls.

If no extra package is loaded, then factorizations are computed recursively; and thus slowly. If NormalizInterface is loaded, then a system of equations is solved with Normaliz, and the performance is much better. If 4ti2Interface is loaded instead, then factorizations are calculated using zsolve command of 4ti2.

gap> FactorizationsVectorWRTList([5,5],[[2,0],[0,2],[1,1]]);
[ [ 2, 2, 1 ], [ 1, 1, 3 ], [ 0, 0, 5 ] ]


##### 11.4-2 ElasticityOfAffineSemigroup
 ‣ ElasticityOfAffineSemigroup( a ) ( operation )

a is an affine semigroup. The output is the elasticity of a (defined as for numerical semigroups).

The procedure used is based on [Phi10], where it is shown that the elasticity can be computed by using circuits. The set of circuits is calculated using [ES96].

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> ElasticityOfAffineSemigroup(a);
1


##### 11.4-3 DeltaSetOfAffineSemigroup
 ‣ DeltaSetOfAffineSemigroup( a ) ( function )

a is an affine semigroup. The output is the Delta set of a (defined as for numerical semigroups). The the procedure used is explained in [GSOW17].

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> DeltaSetOfAffineSemigroup(a);
[  ]
gap> s:=NumericalSemigroup(10,13,15,47);;
gap> a:=AsAffineSemigroup(s);;
gap> DeltaSetOfAffineSemigroup(a);
[ 1, 2, 3, 5 ]


##### 11.4-4 CatenaryDegreeOfAffineSemigroup
 ‣ CatenaryDegreeOfAffineSemigroup( a ) ( function )

a is an affine semigroup. The output is the catenary degree of a (defined as for numerical semigroups).

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> CatenaryDegreeOfAffineSemigroup(a);
2


##### 11.4-5 EqualCatenaryDegreeOfAffineSemigroup
 ‣ EqualCatenaryDegreeOfAffineSemigroup( a ) ( function )

a is an affine semigroup. The output is the equal catenary degree of a (defined as for numerical semigroups).

This function relies on the results presented in [GSOSRN13].

##### 11.4-6 HomogeneousCatenaryDegreeOfAffineSemigroup
 ‣ HomogeneousCatenaryDegreeOfAffineSemigroup( a ) ( function )

a is an affine semigroup. The output is the homogeneous catenary degree of a (defined as for numerical semigroups).

This function is based on [GSOSRN13].

##### 11.4-7 MonotoneCatenaryDegreeOfAffineSemigroup
 ‣ MonotoneCatenaryDegreeOfAffineSemigroup( a ) ( function )

a is an affine semigroup. The output is the monotone catenary degree of a (defined as for numerical semigroups), computed as explained in [Phi10].

gap> a:=AffineSemigroup("inequalities",[[2,-1],[-1,3]]);
<Affine semigroup>
gap> GeneratorsOfAffineSemigroup(a);
[ [ 1, 1 ], [ 1, 2 ], [ 2, 1 ], [ 3, 1 ] ]
gap> CatenaryDegreeOfAffineSemigroup(a);
3
gap> EqualCatenaryDegreeOfAffineSemigroup(a);
2
gap> HomogeneousCatenaryDegreeOfAffineSemigroup(a);
3
gap> MonotoneCatenaryDegreeOfAffineSemigroup(a);
3


##### 11.4-8 TameDegreeOfAffineSemigroup
 ‣ TameDegreeOfAffineSemigroup( a ) ( operation )

a is an affine semigroup. The output is the tame degree of a (defined as for numerical semigroups). If a is given by equations (or its equations are known), then the procedure explained in [GSOW17] is used.

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> TameDegreeOfAffineSemigroup(a);
2


##### 11.4-9 OmegaPrimalityOfElementInAffineSemigroup
 ‣ OmegaPrimalityOfElementInAffineSemigroup( v, a ) ( operation )

v is a list of nonnegative integers and a is an affine semigroup. The output is the omega primality of a (defined as for numerical semigroups). Returns 0 if the element is not in the semigroup.

The implementation of this procedure is performed as explained in [BGSG11] (also, if the semigroup has defining equations, then it takes advantage of this fact as explained in this reference).

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> OmegaPrimalityOfElementInAffineSemigroup([5,5],a);
6


##### 11.4-10 OmegaPrimalityOfAffineSemigroup
 ‣ OmegaPrimalityOfAffineSemigroup( a ) ( function )

a is an affine semigroup. The output is the omega primality of a (defined as for numerical semigroups).

gap> a:=AffineSemigroup([2,0],[0,2],[1,1]);;
gap> OmegaPrimalityOfAffineSemigroup(a);
2

Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 13 A B C Bib Ind

generated by GAPDoc2HTML