Goto Chapter: Top 1 2 3 4 5 6 7 8 Bib Ind

### 4 Groupoids

A groupoid is a (mathematical) category in which every element is invertible. It consists of a set of pieces, each of which is a connected groupoid. The usual terminology is connected component', but in GAP component' is used for record component', so we use the term single piece.

The simplest form for a single piece groupoid is the direct product of a group and a complete digraph, and so is determined by a set of objects obs = Ω (the least of which is the root object), and a root group grp = G. Then the elements of the groupoid are arrows g : o_1 -> o_2, stored as triples [g,o1,o2], where g ∈ G and o_1,o_2 ∈ Ω. The objects will generally be chosen to be consecutive negative integers, but any suitable ordered set is acceptable, and consecutive' is not a requirement. The root group will usually be taken to be a permutation group, but pc-groups, fp-groups and matrix groups are also supported.

A group may be considered as a single piece groupoid with one object.

A groupoid is a set of one or more single piece groupoids, its pieces, and is represented as IsGroupoidRep, with attribute PiecesOfGroupoid.

A groupoid is homogeneous if it has two of more isomorphic pieces, with identical groups. The special case of homogeneous, discrete groupoids, where each piece has a single object, is given its own representation. These are used in the XMod package as the source of a crossed modules of groupoids.

For the definitions of the standard properties of groupoids we refer to R. Brown's book Topology'' [Bro88], recently revised and reissued as Topology and Groupoids'' [Bro06].

#### 4.1 Groupoids: their properties and attributes

##### 4.1-1 SinglePieceGroupoid
 ‣ SinglePieceGroupoid( grp, obs ) ( operation )
 ‣ Groupoid( args ) ( function )
 ‣ DomainWithSingleObject( gp, obj ) ( operation )

The simplest construction of a groupoid is as the direct product of a group and a complete digraph. Such a groupoid will be called a standard groupoid. Many subgroupoids of such a groupoid do not have this simple form, and will be considered in section 4.3. The global function Groupoid will normally find the appropriate constructor to call, the options being:

• the object group, a set of objects;

• a group being converted to a groupoid, a single object;

• a list of groupoids which have already been constructed (see 4.1-4).

Methods for ViewObj, PrintObj and Display are provided for groupoids and the other types of object in this package. Users are advised to supply names for all the groups and groupoids they construct.

gap> s4 := Group( (1,2,3,4), (3,4) );;
gap> d8 := Subgroup( s4, [ (1,2,3,4), (1,3) ] );;
gap> SetName( s4, "s4" );  SetName( d8, "d8" );
gap> Gs4 := SinglePieceGroupoid( s4, [-15 .. -11] );
single piece groupoid: < s4, [ -15 .. -11 ] >
gap> Gd8 := Groupoid( d8, [-9,-8,-7] );
single piece groupoid: < d8, [ -9, -8, -7 ] >
gap> c6 := Group( (5,6,7)(8,9) );;
gap> SetName( c6, "c6" );
gap> Gc6 := DomainWithSingleObject( c6, -6 );
single piece groupoid: < c6, [ -6 ] >
gap> SetName( Gs4, "Gs4" );  SetName( Gd8, "Gd8" );  SetName( Gc6, "Gc6" );

##### 4.1-2 ObjectList
 ‣ ObjectList( gpd ) ( attribute )
 ‣ RootObject( gpd ) ( attribute )
 ‣ RootGroup( gpd ) ( attribute )
 ‣ ObjectGroup( gpd, obj ) ( operation )

The ObjectList of a groupoid is the sorted list of objects. The RootObject in a single-piece groupoid is the object with least label. A loop is an arrow of the form g : o -> o, and the loops at a particular object o form a group, the ObjectGroup at o. The RootGroup is the ObjectGroup at the RootObject.

In the example the groupoids Gf2c6 and Gabc show that the objects need not be integers.

gap> ObjectList( Gs4 );
[ -15 .. -11 ]
gap> [ RootObject( Gd8 ), RootGroup( Gc6 ), ObjectGroup( Gs4, -11 ) ];
[ -9, c6, s4 ]
gap> f2 := FreeGroup(2);;
gap> Gf2c6 := Groupoid( c6, GeneratorsOfGroup(f2) );
single piece groupoid: < c6, [ f1, f2 ] >
gap> Arrow( Gf2c6, (5,7,6), f2.1, f2.2 );
[(5,7,6) : f1 -> f2]
gap> Gabc := Groupoid( d8, [ "a", "b", "c" ] );
single piece groupoid: < d8, [ "a", "b", "c" ] >
gap> Arrow( Gabc, (2,4), "c", "b" );
[(2,4) : c -> b]

##### 4.1-3 IsPermGroupoid
 ‣ IsPermGroupoid( gpd ) ( property )
 ‣ IsPcGroupoid( gpd ) ( property )
 ‣ IsFpGroupoid( gpd ) ( property )
 ‣ IsMatrixGroupoid( gpd ) ( property )
 ‣ IsFreeGroupoid( gpd ) ( property )

A groupoid is a permutation groupoid if all its pieces have permutation groups. Most of the examples in this chapter are permutation groupoids, but in principle any type of group known to GAP may be used.

In the following example Gf2 is an fp-groupoid and also a free groupoid, Gq8 is a pc-groupoid, and Ggl43 is a matrix groupoid. See section 5.7 for matrix representations of groupoids.

gap> f2 := FreeGroup( 2 );;
gap> Gf2 := Groupoid( f2, -22 );;
gap> SetName( f2, "f2" );  SetName( Gf2, "Gf2" );
gap> q8 := SmallGroup( 8, 4 );;
gap> Gq8 := Groupoid( q8, [ -28, -27 ] );;
gap> SetName( q8, "q8" );  SetName( Gq8, "Gq8" );
gap> gl43 := SpecialLinearGroup( 4, 3 );;
gap> Ggl43 := SinglePieceGroupoid( gl43, [ -35..-31 ] );;
gap> SetName( gl43, "gl43" );  SetName( Ggl43, "Ggl43" );
gap> [ IsMatrixGroupoid( Ggl43 ), IsFpGroupoid( Gf2 ), IsFreeGroupoid( Gf2 ),
>      IsPcGroupoid( Gq8 ), IsPermGroupoid( Gs4 ) ];
[ true, true, true, true, true ]

##### 4.1-4 UnionOfPieces
 ‣ UnionOfPieces( pieces ) ( operation )
 ‣ Pieces( gpd ) ( attribute )
 ‣ Size( gpd ) ( attribute )
 ‣ ReplaceOnePieceInUnion( U, old_piece, new_piece ) ( operation )

When a groupoid consists of two or more pieces, we require their object lists to be disjoint. The operation UnionOfPieces and the attribute Pieces, introduced in section 2.5, are also used for groupoids. The pieces are sorted by the least object in their object lists. The ObjectList is the sorted concatenation of the objects in the pieces.

The Size of a groupoid is the number of its arrows. For a single piece groupoid, this is the product of the size of the group with the square of the number of objects. For a non-connected groupoid, the size is the sum of the sizes of its pieces.

One of the pieces in a groupoid may be replaced by an alternative piece using the operation ReplaceOnePieceInUnion. The old_piece may be either the position of the piece to be replaced, or one of the pieces in U. The objects in the new piece may or may not overlap the objects in the piece being removed -- we just require that the object lists in the new union are disjoint.

gap> U3 := UnionOfPieces( [ Gc6, Gd8, Gs4 ] );;
gap> Display( U3 );
groupoid with 3 pieces:
< objects: [ -15 .. -11 ]
group: s4 = <[ (1,2,3,4), (3,4) ]> >
< objects: [ -9, -8, -7 ]
group: d8 = <[ (1,2,3,4), (1,3) ]> >
< objects: [ -6 ]
group: c6 = <[ (5,6,7)(8,9) ]> >
gap> Pieces( U3 );
[ Gs4, Gd8, Gc6 ]
gap> ObjectList( U3 );
[ -15, -14, -13, -12, -11, -9, -8, -7, -6 ]
gap> U2 := Groupoid( [ Gf2, Gq8 ] );;
gap> [ Size(Gs4), Size(Gd8), Size(Gc6), Size(U3) ];
[ 600, 72, 6, 678 ]
gap> [ Size(Gf2), Size(Gq8), Size(U2) ];
[ infinity, 32, infinity ]
gap> U5 := UnionOfPieces( [ U3, U2 ] );
groupoid with 5 pieces:
[ Gq8, Gf2, Gs4, Gd8, Gc6 ]
gap> Display( U5 );
groupoid with 5 pieces:
< objects: [ -28, -27 ]
group: q8 = <[ f1, f2, f3 ]> >
< objects: [ -22 ]
group: f2 = <[ f1, f2 ]> >
< objects: [ -15 .. -11 ]
group: s4 = <[ (1,2,3,4), (3,4) ]> >
< objects: [ -9, -8, -7 ]
group: d8 = <[ (1,2,3,4), (1,3) ]> >
< objects: [ -6 ]
group: c6 = <[ (5,6,7)(8,9) ]> >
gap> V5 := ReplaceOnePieceInUnion( U5, 3, Ggl43 );
groupoid with 5 pieces:
[ Ggl43, Gq8, Gf2, Gd8, Gc6 ]
gap> ObjectList( V5 );
[ -35, -34, -33, -32, -31, -28, -27, -22, -9, -8, -7, -6 ]
gap> U5 = V5;
false
gap> W5 := ReplaceOnePieceInUnion( V5, Gc6, Gs4 );
groupoid with 5 pieces:
[ Ggl43, Gq8, Gf2, Gs4, Gd8 ]
gap> ObjectList( W5 );
[ -35, -34, -33, -32, -31, -28, -27, -22, -15, -14, -13, -12, -11, -9, -8, -7
]

##### 4.1-5 HomogeneousGroupoid
 ‣ HomogeneousGroupoid( gpd, oblist ) ( operation )
 ‣ HomogeneousDiscreteGroupoid( gp, obs ) ( operation )

Special functions are provided for the case where a groupoid has more than one connected component, and when these components are identical except for their object sets. Such groupoids are said to be homogeneous.

The operation HomogeneousGroupoid is used when the components each contain more than one object. The arguments consist of a single piece groupoid gpd and a list of lists of objects oblist, each of whose lists has the same length as the object list obs of gpd. Note that gpd is not included as one of the pieces in the output unless obs is included as one of the lists in oblist.

The operation HomogeneousDiscreteGroupoid is used when the components each have a single object. In this case the first argument is just a group -- the root group for each component. These groupoids are used in the XMod package as the source of many crossed modules of groupoids.

Both types of groupoid have the property IsHomogeneousDomainWithObjects. In the latter case a separate representation IsHomogeneousDiscreteGroupoidRep is used.

gap> Hd8 := HomogeneousGroupoid( Gd8, [ [-12,-11,-10], [-16,-15,-14] ] );
homogeneous groupoid with 2 pieces:
1:  single piece groupoid: < d8, [ -16, -15, -14 ] >
2:  single piece groupoid: < d8, [ -12, -11, -10 ] >
gap> Size(Hd8);   ## 8x3x3 + 8x3x3
144
gap> IsHomogeneousDomainWithObjects( Hd8 );
true
gap> Hc6 := HomogeneousDiscreteGroupoid( c6, [-7..-4] );
homogeneous, discrete groupoid: < c6, [ -7 .. -4 ] >
gap> Size(Hc6);   ## 6x4
24
gap> RepresentationsOfObject(Gd8);
[ "IsComponentObjectRep", "IsAttributeStoringRep", "IsMWOSinglePieceRep" ]
gap> RepresentationsOfObject(Hd8);
[ "IsComponentObjectRep", "IsAttributeStoringRep", "IsPiecesRep" ]
gap> RepresentationsOfObject(Hc6);
[ "IsComponentObjectRep", "IsAttributeStoringRep",
"IsHomogeneousDiscreteGroupoidRep" ]
gap> ktpo := KnownTruePropertiesOfObject(Hc6);;
gap> ans :=
> [ "CanEasilyCompareElements", "CanEasilySortElements",
>   "IsDuplicateFree", "IsAssociative", "IsCommutative",
>   "IsDiscreteDomainWithObjects", "IsHomogeneousDomainWithObjects" ];;
gap> ForAll( ans, a -> ( a in ktpo ) );
true

##### 4.1-6 DirectProductOp
 ‣ DirectProductOp( list, gpd ) ( operation )
 ‣ Projection( gpd, pos ) ( operation )
 ‣ Embedding( gpd, pos ) ( operation )

The direct product of groupoids G,H has as group the direct product of the groups in G and H and as object list the cartesian product of their object lists.

gap> prod := DirectProductOp( [Gd8,Gc6], Gd8 );
single piece groupoid: < Group( [ (1,2,3,4), (1,3), (5,6,7)(8,9) ] ),
[ [ -9, -6 ], [ -8, -6 ], [ -7, -6 ] ] >
gap> Projection( prod, 1 );
groupoid homomorphism :
[ [ [(1,2,3,4) : [ -9, -6 ] -> [ -9, -6 ]], [(1,3) : [ -9, -6 ] -> [ -9, -6 ]]
, [(5,6,7)(8,9) : [ -9, -6 ] -> [ -9, -6 ]],
[() : [ -9, -6 ] -> [ -8, -6 ]], [() : [ -9, -6 ] -> [ -7, -6 ]] ],
[ [(1,2,3,4) : -9 -> -9], [(1,3) : -9 -> -9], [() : -9 -> -9],
[() : -9 -> -8], [() : -9 -> -7] ] ]
gap> Embedding(prod,2);
groupoid homomorphism :
[ [ [(5,6,7)(8,9) : -6 -> -6] ],
[ [(5,6,7)(8,9) : [ -9, -6 ] -> [ -9, -6 ]] ] ]
gap> DirectProductInfo( prod );
rec( embeddings := [ , groupoid homomorphism :
[ [ [(5,6,7)(8,9) : -6 -> -6] ],
[ [(5,6,7)(8,9) : [ -9, -6 ] -> [ -9, -6 ]] ] ] ], first := Gd8,
groupoids := [ Gd8, Gc6 ], groups := [ d8, c6 ],
objectlists := [ [ -9, -8, -7 ], [ -6 ] ],
projections := [ groupoid homomorphism :
[ [ [(1,2,3,4) : [ -9, -6 ] -> [ -9, -6 ]],
[(1,3) : [ -9, -6 ] -> [ -9, -6 ]],
[(5,6,7)(8,9) : [ -9, -6 ] -> [ -9, -6 ]],
[() : [ -9, -6 ] -> [ -8, -6 ]],
[() : [ -9, -6 ] -> [ -7, -6 ]] ],
[ [(1,2,3,4) : -9 -> -9], [(1,3) : -9 -> -9], [() : -9 -> -9],
[() : -9 -> -8], [() : -9 -> -7] ] ] ] )

#### 4.2 Groupoid elements; stars; costars; homsets

##### 4.2-1 GroupoidElement
 ‣ GroupoidElement( gpd, elt, tail, head ) ( operation )
 ‣ ElementOfArrow( elt ) ( operation )
 ‣ TailOfArrow( elt ) ( operation )
 ‣ HeadOfArrow( elt ) ( operation )

The operation GroupoidElement is a synonym for the operation Arrow, as described in subsection 2.1-2. To recapitulate, an arrow e consists of a group element, ElementOfArrow(e); the tail (source) object, TailOfArrow(e); and the head (target) object, HeadOfArrow(e). Arrows have a partial composition: two arrows may be multiplied when the head of the first coincides with the tail of the second. If an attempt is made to multiply arrows where this condition does not hold, then the value fail is returned.

gap> e1 := GroupoidElement( Gd8, (1,2,3,4), -9, -8 );
[(1,2,3,4) : -9 -> -8]
gap> e2 := Arrow( Gd8, (1,3), -8, -7 );
[(1,3) : -8 -> -7]
gap> Print( [ ElementOfArrow(e1), TailOfArrow(e1), HeadOfArrow(e1) ], "\n" );
[ (1,2,3,4), -9, -8 ]
gap> prod := e1*e2;
[(1,2)(3,4) : -9 -> -7]
gap> e2*e1;
fail
gap> e3 := Arrow( Gd8, (2,4), -7, -9 );;
gap> loop := prod*e3;
[(1,4,3,2) : -9 -> -9]
gap> loop^2;
[(1,3)(2,4) : -9 -> -9]

##### 4.2-2 IdentityArrow
 ‣ IdentityArrow( gpd, obj ) ( operation )

The identity arrow 1_o of G at object o is (e:o -> o) where e is the identity element in the object group. The inverse arrow e^-1 of e = (c : p -> q) is (c^-1 : q -> p), so that e*e^-1=1_p and e^-1*e = 1_q.

gap> i8 := IdentityArrow( Gd8, -8 );
[() : -8 -> -8]
gap> [ e1*i8, i8*e1, e1^-1];
[ [(1,2,3,4) : -9 -> -8], fail, [(1,4,3,2) : -8 -> -9] ]

##### 4.2-3 Order
 ‣ Order( arr ) ( attribute )

A groupoid element is a loop when the tail and head coincide. In this case the order of the element is defined to be the order of its group element.

gap> i8; Order(i8);
[() : -8 -> -8]
1
gap> loop; Order(loop);
[(1,4,3,2) : -9 -> -9]
4

##### 4.2-4 ObjectStar
 ‣ ObjectStar( gpd, obj ) ( operation )
 ‣ ObjectCostar( gpd, obj ) ( operation )
 ‣ Homset( gpd, tail, head ) ( operation )

The star at obj is the set of arrows which have obj as tail, while the costar is the set of arrows which have obj as head. The homset from obj1 to obj2 is the set of arrows with the specified tail and head, and so is bijective with the elements of the object groups. Thus every star and every costar is a union of homsets. The identity arrow at an object is a left identity for the star and a right identity for the costar at that object.

In order not to create unneccessarily long lists, these operations return objects of type IsHomsetCosetsRep for which an Iterator is provided. (An Enumerator is not yet implemented.)

gap> star9 := ObjectStar( Gd8, -9 );
<star at [ -9 ] with group d8>
gap> Size( star9 );
24
gap> for e in star9 do
>      if ( Order( ElementOfArrow(e) ) = 4 ) then Print( e, "\n" ); fi;
>    od;
[(1,4,3,2) : -9 -> -9]
[(1,4,3,2) : -9 -> -8]
[(1,4,3,2) : -9 -> -7]
[(1,2,3,4) : -9 -> -9]
[(1,2,3,4) : -9 -> -8]
[(1,2,3,4) : -9 -> -7]
gap> costar6 := ObjectCostar( Gc6, -6 );
<costar at [ -6 ] with group c6>
gap> Size( costar6 );
6
gap> hsetq8 := Homset( Gq8, -28, -27 );
<homset -28 -> -27 with group q8>
gap> for e in hsetq8 do Print(e,"\n"); od;
[<identity> of ... : -28 -> -27]
[f3 : -28 -> -27]
[f2 : -28 -> -27]
[f2*f3 : -28 -> -27]
[f1 : -28 -> -27]
[f1*f3 : -28 -> -27]
[f1*f2 : -28 -> -27]
[f1*f2*f3 : -28 -> -27]

#### 4.3 Subgroupoids

##### 4.3-1 Subgroupoid
 ‣ Subgroupoid( args ) ( function )
 ‣ SubgroupoidByPieces( gpd, obhoms ) ( operation )
 ‣ IsSubgroupoid( gpd, sgpd ) ( operation )
 ‣ IsWideSubgroupoid( gpd, sgpd ) ( operation )

A subgroupoid S of a groupoid G has as objects some subset of the objects of G. It is wide in G if both groupoids have the same object set. It is full if, for any two objects in S, the Homset is the same as that in G. The arrows of S are a subset of those of G, closed under multiplication and with tail and head in the chosen object set.

There are a variety of constructors for a subgroupoid of a standard groupoid, and the most general is the operation SubgroupoidByPieces. Its two parameters are a groupoid and a list of pieces, each piece being specified as a list [sgp,obs], where sgp is a subgroup of the root group in that piece, and obs is a subset of the objects in that piece.

gap> c4 := Subgroup( d8, [ (1,2,3,4) ] );;
gap> k4 := Subgroup( d8, [ (1,2)(3,4), (1,3)(2,4) ] );;
gap> SetName( c4, "c4" );  SetName( k4, "k4" );
gap> Ud8 := Subgroupoid( Gd8, [ [ k4, [-9] ], [ c4, [-8,-7] ] ] );;
gap> SetName( Ud8, "Ud8" );
gap> Display( Ud8 );
groupoid with 2 pieces:
< objects: [ -9 ]
group: k4 = <[ (1,2)(3,4), (1,3)(2,4) ]> >
< objects: [ -8, -7 ]
group: c4 = <[ (1,2,3,4) ]> >
gap> [ Parent( Ud8 ), IsWide( Gd8, Ud8 ) ];
[ Gd8, true ]
gap> genf2b := List( GeneratorsOfGroup(f2), g -> g^2 );
[ f1^2, f2^2 ]
gap> f2b := Subgroup( f2, genf2b );;
gap> SU2 := SubgroupoidByPieces( U2, [ [q8,[-27]], [f2b,[-22]] ] );
groupoid with 2 pieces:
1:  single piece groupoid: < q8, [ -27 ] >
2:  single piece groupoid: < Group( [ f1^2, f2^2 ] ), [ -22 ] >
gap> IsWideSubgroupoid( U2, SU2 );
false
gap> IsSubgroupoid( Gf2, Groupoid( f2b, [-22] ) );
true

##### 4.3-2 FullSubgroupoid
 ‣ FullSubgroupoid( gpd, obs ) ( operation )
 ‣ FullTrivialSubgroupoid( gpd ) ( attribute )

The FullSubgroupoid of a groupoid gpd on a subset obs of its objects contains all the arrows of gpd with tail and head in obs. A trivial subgroupoid has trivial object groups, but need not be discrete. A single piece trivial groupoid is sometimes called a tree groupoid. (The term identity subgroupoid was used in versions up to 1.14.) The global function Subgroupoid should call the appropriate operation.

gap> FullSubgroupoid( U3, [-7,-6] );
groupoid with 2 pieces:
1:  single piece groupoid: < d8, [ -7 ] >
2:  single piece groupoid: < c6, [ -6 ] >
gap> FullTrivialSubgroupoid( Ud8 );
groupoid with 2 pieces:
1:  single piece groupoid: < id(k4), [ -9 ] >
2:  single piece groupoid: < id(c4), [ -8, -7 ] >

##### 4.3-3 DiscreteSubgroupoid
 ‣ DiscreteSubgroupoid( gpd, sgps, obs ) ( operation )
 ‣ MaximalDiscreteSubgroupoid( gpd ) ( attribute )
 ‣ DiscreteTrivialSubgroupoid( gpd ) ( attribute )

A subgroupoid is discrete if it is a union of groups. The MaximalDiscreteSubgroupoid of gpd is the union of all the single-object full subgroupoids of gpd.

gap> DiscreteSubgroupoid( U3, [ c4, k4 ], [-9,-7] );
groupoid with 2 pieces:
1:  single piece groupoid: < c4, [ -9 ] >
2:  single piece groupoid: < k4, [ -7 ] >
gap> MaximalDiscreteSubgroupoid(U2);
groupoid with 3 pieces:
1:  single piece groupoid: < q8, [ -28 ] >
2:  single piece groupoid: < q8, [ -27 ] >
3:  single piece groupoid: < f2, [ -22 ] >
gap> DiscreteTrivialSubgroupoid( U2 );
groupoid with 3 pieces:
1:  single piece groupoid: < id(q8), [ -28 ] >
2:  single piece groupoid: < id(q8), [ -27 ] >
3:  single piece groupoid: < id(f2), [ -22 ] >

##### 4.3-4 SubgroupoidWithRays
 ‣ SubgroupoidWithRays( gpd, sgp, rays ) ( operation )
 ‣ RaysOfGroupoid( gpd ) ( operation )
 ‣ RayElementsOfGroupoid( gpd ) ( operation )

If groupoid G is of type IsDirectProductWithCompleteDigraph with group g and n objects, then a typical wide subgroupoid H of G is formed by choosing a subgroup h of g to be the object group at the root object q, and an arrow r : q -> p for each of the objects p. The chosen loop arrow at q must be the identity arrow. These n arrows are called the rays of the subgroupoid. The arrows in the homset from p to p' have the form r^-1xr' where r,r' are the rays from q to p,p' respectively, and x ∈ h.

The operation RaysOfGroupoid returns a list of arrows, one for each object, while the operation RayElementsOfGroupoid returns the list of group elements in these arrows.

In the following example we construct a subgroupoid with rays on three of the five objects. It is therefore necessary to construct the full subgroupoid on these three objects first.

Note that it is also possible to construct a subgroupoid with rays of a subgroupoid with rays.

Note also that the function Ancestor provides an iteration of Parent.

gap> Hs4 := FullSubgroupoid( Gs4, [-14,-13,-12] );;
gap> SetName( Hs4, "Hs4" );
gap> Hd8a := SubgroupoidWithRays( Hs4, d8, [(),(2,3),(3,4)] );
single piece groupoid with rays: < d8, [ -14, -13, -12 ], [ (), (2,3), (3,4)
] >
gap> hs1413 := Homset( Hd8a, -14, -13 );
<homset -14 -> -13 with group d8>
gap> for e in hs1413 do  Print(e,", "); od;  Print( "\n");
[(2,3) : -14 -> -13], [(2,4,3) : -14 -> -13], [(1,2,4,3) : -14 -> -13], [
(1,2,3) : -14 -> -13], [(1,4,2) : -14 -> -13], [(1,4) : -14 -> -13], [
(1,3,4) : -14 -> -13], [(1,3,4,2) : -14 -> -13],
gap> Hd8b := SubgroupoidWithRays( Hs4, d8, [(),(1,2,3),(1,2,4)] );
single piece groupoid with rays: < d8, [ -14, -13, -12 ],
[ (), (1,2,3), (1,2,4) ] >
gap> Hd8a = Hd8b;
true
gap> SetName( Hd8b, "Hd8b" );
gap> RayElementsOfGroupoid( Hd8b );
[ (), (1,2,3), (1,2,4) ]
gap> Parent( Hd8a );
Hs4
gap> Ancestor( Hd8a );
Gs4
gap> Fd8a := FullSubgroupoid( Hd8a, [-13,-12] );
single piece groupoid with rays: < Group( [ (1,3,2,4), (1,2) ] ),
[ -13, -12 ], [ (), (2,4,3) ] >
gap> Kd8a := SubgroupoidWithRays( Fd8a, k4, [ (), (1,3) ] );
single piece groupoid with rays: < k4, [ -13, -12 ], [ (), (1,3) ] >

##### 4.3-5 SinglePieceSubgroupoidByGenerators
 ‣ SinglePieceSubgroupoidByGenerators( parent, gens ) ( operation )

A set of arrows generates a groupoid by taking all possible products and inverses. So far, the only implementation is for the case of loops generating a group at an object o together with a set of rays from o, where o is not the least object. A suitably large supergroupoid, which must be a direct product with a complete digraph, should be provided. This is the case needed for ConjugateGroupoid in section 4.5-2. Other cases will be added as time permits.

gap> u := Arrow( Gs4, (1,2,3), -15, -13 );
[(1,2,3) : -15 -> -13]
gap> gensa := GeneratorsOfGroupoid( Hd8a );
[ [(1,2,3,4) : -14 -> -14], [(1,3) : -14 -> -14], [(2,3) : -14 -> -13],
[(3,4) : -14 -> -12] ]
gap> imsa := List( gensa, g -> g^u );
[ [(1,2,3,4) : -14 -> -14], [(1,3) : -14 -> -14], [(1,3) : -14 -> -15],
[(3,4) : -14 -> -12] ]
gap> C := SinglePieceSubgroupoidByGenerators( Gs4, imsa );
single piece groupoid with rays: < Group( [ (1,4,3,2), (1,3) ] ),
[ -15, -14, -12 ], [ (), (1,3), (1,4,3) ] >

#### 4.4 Left, right and double cosets

##### 4.4-1 RightCoset
 ‣ RightCoset( G, U, elt ) ( operation )
 ‣ RightCosetRepresentatives( G, U ) ( operation )
 ‣ LeftCoset( G, U, elt ) ( operation )
 ‣ LeftCosetRepresentatives( G, U ) ( operation )
 ‣ LeftCosetRepresentativesFromObject( G, U, obj ) ( operation )
 ‣ DoubleCoset( G, U, elt, V ) ( operation )
 ‣ DoubleCosetRepresentatives( G, U, V ) ( operation )

If U is a wide subgroupoid of G, the right cosets Ug of U in G are the equivalence classes for the relation on the arrows of G where g1 is related to g2 if and only if g2 = u*g1 for some arrow u of U. The right coset containing g is written Ug. These right cosets partition the costars of G and, in particular, the costar U1_o of U at object o, so that (unlike groups) U is itself a coset only when G has a single object.

The right coset representatives for U in G form a list containing one arrow for each coset where, in a particular piece of U, the group element chosen is the right coset representative of the group of U in the group of G.

Similarly, the left cosets gU refine the stars of G, while double cosets are unions of left cosets and right cosets. The operation LeftCosetRepresentativesFromObject( G, U, obj ) is used in Chapter 4, and returns only those representatives which have tail at obj.

As with stars and homsets, these cosets are implemented with representation IsHomsetCosetsRep and provided with an iterator. Note that, when U has more than one piece, cosets may have differing lengths.

In the example the representative for the right coset re2 is the last one in the list rcrd8, namely [(2,4):-8->-7].

gap> re2 := RightCoset( Gd8, Ud8, e2 );
RightCoset(single piece groupoid: < c4, [ -8, -7 ] >,[(1,3) : -8 -> -7])
gap> for x in re2 do Print( x, "\n" ); od;
[(1,3) : -8 -> -7]
[(1,3) : -7 -> -7]
[(2,4) : -8 -> -7]
[(2,4) : -7 -> -7]
[(1,4)(2,3) : -8 -> -7]
[(1,4)(2,3) : -7 -> -7]
[(1,2)(3,4) : -8 -> -7]
[(1,2)(3,4) : -7 -> -7]
gap> rcrd8 := RightCosetRepresentatives( Gd8, Ud8 );
[ [() : -9 -> -9], [() : -9 -> -8], [() : -9 -> -7], [(2,4) : -9 -> -9],
[(2,4) : -9 -> -8], [(2,4) : -9 -> -7], [() : -8 -> -9], [() : -8 -> -8],
[() : -8 -> -7], [(2,4) : -8 -> -9], [(2,4) : -8 -> -8], [(2,4) : -8 -> -7]
]
gap> lcr7 := LeftCosetRepresentativesFromObject( Gd8, Ud8, -7 );
[ [() : -7 -> -9], [(2,4) : -7 -> -9], [() : -7 -> -8], [(2,4) : -7 -> -8] ]

#### 4.5 Conjugation

##### 4.5-1 \^
 ‣ \^( e1, e ) ( operation )

Conjugation by an arrow e = (c : p -> q) is the groupoid inner automorphism (see section 5.6) defined as follows. There are two cases to consider. In the case p ≠ q,

• objects p,q are interchanged, and the remaining objects are fixed;

• loops at p,q: (b: p -> p) ↦ (b^c : q -> q) and (b: q -> q) ↦ (b^c^-1} : p -> p);

• arrows between p and q: (b : p -> q) ↦ (c^-1bc^-1 : q -> p) and (b : q -> p) ↦ (cbc : p -> q);

• costars at p,q: (b : r -> p) ↦ (bc : r -> q) and (b : r -> q) ↦ (bc^-1 : r -> p);

• stars at p,q: (b : p -> r) ↦ (c^-1b : -> q) and (b : q -> r) ↦ (cb : p -> r);

• the remaining arrows are unchanged.

In the case p=q,

• all the objects are fixed;

• loops at p are conjugated by c, so (b : p -> p) ↦ (b^c : p -> p);

• the rest of the costar and star at p are permuted,

(b : r \to p) \mapsto (bc : r \to p) \quad\mbox{and}\quad (b : p \to r) \mapsto (c^{-1}b : p \to r);

• the remaining arrows are unchanged.

The details of this construction may be found in section 3.2 of [AW10].

gap> x := Arrow( Gd8, (1,3), -9, -9 );;
gap> y := Arrow( Gd8, (1,2,3,4), -8, -9 );;
gap> z := Arrow( Gd8, (1,2)(3,4), -9, -7 );;
gap> w := Arrow( Gd8, (1,2,3,4), -7, -8 );;
gap> ##  conjugation with elements x, y, and z in Gd8:
gap> x^y;
[(2,4) : -8 -> -8]
gap> x^z;
[(2,4) : -7 -> -7]
gap> y^x;
[() : -8 -> -9]
gap> y^z;
[(2,4) : -8 -> -7]
gap> z^x;
[(1,4,3,2) : -9 -> -7]
gap> z^y;
[(2,4) : -8 -> -7]
gap> w^z
[(1,3) : -9 -> -8]

##### 4.5-2 ConjugateGroupoid
 ‣ ConjugateGroupoid( gpd, e ) ( operation )

When H is a subgroupoid of a groupoid G and a is an arrow of G, then the conjugate of H by a is the subgroupoid generated by the conjugates of the generators of H.

gap> ConjugateGroupoid( Hd8a, u^-1 );
single piece groupoid with rays: < Group( [ (1,4,3,2), (1,3) ] ),
[ -15, -14, -12 ], [ (), (1,3), (1,4,3) ] >

More examples of all these operations may be found in the example file groupoids/examples/gpd.g.

Goto Chapter: Top 1 2 3 4 5 6 7 8 Bib Ind

generated by GAPDoc2HTML