[GAP Forum] Permutationgroups
Tim Kohl
tkohl at math.bu.edu
Mon Jul 28 04:07:39 BST 2014
Another not quite as general set of examples may
be obtained by computing right regular representations.
For example, you can compute right regular representations
of all the groups of order 16.
R16:=List(AllSmallGroups(16),G->Action(G,AsList(G),OnRight));
which will all be transitive and fixed point free.
(In particular, the degree will equal the order.)
You can also take a given group G and return all sub-groups of a
given order 'n'
nallsub:=function(G,n)
local i,j,t,A,cG;
A:=[];
cG:=Filtered(ConjugacyClassesSubgroups(G),x->Size(Representative(x))=n);
for i in [1..Size(cG)] do
t := AsList(RightTransversal(G,Normalizer(G,cG[i][1])));
for j in [1..Size(t)] do
AddSet(A,ConjugateGroup(cG[i][1],t[j]));
od;
od;
return(A);
end;
So if the group you pass to this is one of the regular subgroups of
degree=order=d then this will (potentially) churn out examples of order
n<d but of the same degree d.
Of course, regularity will preclude those cases where n does not divide d,
but this will at least generate some examples.
-Tim
On Sun, 27 Jul 2014, Stefan Kohl wrote:
> On Sun, July 27, 2014 5:17 pm, Kurt Ewald wrote:
>
> > how can I construct a Permutationgroup with given Order and Degree.
> >
> > for instance: GroupOrder 12 and Degree 5, I found by accident
> >
> > G:=<(1,2,3),(1,5,2)>
>
> You can find all transitive permutation groups of order n and degree d <= 30 by
>
> AllTransitiveGroups(DegreeAction,d,Size,n);
>
> For example:
>
> gap> AllTransitiveGroups(DegreeAction,6,Size,60);
> [ L(6) = PSL(2,5) = A_5(6) ]
> gap> AllTransitiveGroups(DegreeAction,6,Size,72);
> [ F_36(6):2 = [S(3)^2]2 = S(3) wr 2 ]
> gap> AllTransitiveGroups(DegreeAction,8,Size,32);
> [ [1/4.cD(4)^2]2, 1/2[2^4]4, [4^2]2, E(8):E_4=[2^2]D(4), E(8):4=[1/4.eD(4)^2]2,
> [2^3]4, 1/2[2^4]E(4)=[1/4.dD(4)^2]2, E(8):D_4=[2^3]2^2 ]
> gap> AllTransitiveGroups(DegreeAction,24,Size,240);
> [ t24n570, t24n571, t24n572, t24n573, t24n574, t24n575, t24n576, t24n577, t24n578 ]
>
> The data is taken from the GAP Transitive Groups Library,
> cf. http://www.gap-system.org/Datalib/trans.html.
>
> If -- as your example suggests -- you are also interested in
> intransitive groups, you maybe need to do some programming yourself --
> though for very small degrees you can simply use the following
> brute force approach:
>
> PermGroupsOfGivenDegreeAndOrder := function ( d, n )
>
> return Filtered(List(ConjugacyClassesSubgroups(SymmetricGroup(d)),
> Representative),
> G->Size(G)=n);
> end;
>
> For example:
>
> gap> PermGroupsOfGivenDegreeAndOrder(6,12);
> [ Group([ (3,6,4), (3,4)(5,6) ]), Group([ (1,5,3)(2,6,4), (1,2)(3,4) ]),
> Group([ (1,3)(4,6), (1,4)(2,6)(3,5) ]), Group([ (5,6), (2,3)(4,6) ]) ]
> gap> List(last,Size);
> [ 12, 12, 12, 12 ]
>
> By the way -- your example does not have degree 5, since 4 is fixed:
>
> gap> DegreeAction(Group((1,2,3),(1,5,2)));
> 4
>
> Hope this helps,
>
> Stefan Kohl
>
> -----------------------------------------------------------------------------
> http://www.gap-system.org/DevelopersPages/StefanKohl/
> -----------------------------------------------------------------------------
>
>
>
>
>
>
>
>
> _______________________________________________
> Forum mailing list
> Forum at mail.gap-system.org
> http://mail.gap-system.org/mailman/listinfo/forum
>
More information about the Forum
mailing list