[GAP Forum] IsMinimalNonmonomial(AlternatingGroup(5));

[Marc Keilberg]

A non-solvable minimal non-monomial group must be simple.  Equivalently, a
non-simple minimal nonmonomial group is solvable. For then it has a proper,
non-trivial, normal, monomial and therefore solvable subgroup, the quotient
by which is also monomial and so solvable by assumption. So we can test for
simplicity in the non-solvable case, and we can then see why the method
just kind of dies with an error. Trying to solve this problem for generic
simple groups would likely be extremely computationally intensive and
likely ad hoc depending on the family, as we must potentially check all
(classes) of its subgroups which is generally not a solved problem; even
the classification of maximal subgroups isn't completely settled.  While
the minimal nonmonomial solvable groups are classified, I don't think the
simple ones are.  Even deciding simplicity may be a chore, which may
explain why the method also throws an error on a non-solvable non-simple
group like SmallGroup(120,5) or S_5.

Marc

On Sun, May 2, 2021 at 4:58 AM Sam Tertooy <sam.tertooy at kuleuven.be> wrote:

> Dear Bill,
>
> It seems like there is currently no method installed for non-solvable
> groups. Assuming you're not too worried about performance, you could
> install a naive method for non-solvable groups with the code below (someone
> please correct me if I made a mistake anywhere):
>
> InstallMethod(
>         IsMinimalNonmonomial,
>         [ IsGroup ],
>         function ( G )
>                 local CCSG, cc, H, Q;
>                 if IsSolvableGroup( G ) then
>                         TryNextMethod();
>                 fi;
>                 if IsMonomial( G ) then
>                         return false;
>                 fi;
>                 CCSG := ConjugacyClassesSubgroups( G );
>                 for cc in CCSG do
>                         H := Representative( cc );
>                         if G = H or IsTrivial( H ) then
>                                 continue;
>                         fi;
>                         if not IsMonomial( H ) then
>                                 return false;
>                         fi;
>                         if Size( cc ) = 1 then
>                                 Q := FactorGroupNC( G, H );
>                                 if not IsMonomial( Q ) then
>                                         return false;
>                                 fi;
>                         fi;
>                 od;
>                 return true;
>         end
> );
>
>
> gap> AllGroups( Size, [ 1..100 ], IsMinimalNonmonomial );
> [ <pc group of size 24 with 4 generators>, Alt( [ 1 .. 5 ] ) ]
>
> Best,
> Sam
> ________________________________________
> From: Bill Allombert <Bill.Allombert at math.u-bordeaux.fr>
> Sent: 02 May 2021 00:21
> To: GAP Forum
> Subject: [GAP Forum] IsMinimalNonmonomial(AlternatingGroup(5));
>
> Dear Forum,
>
> I found
>
> gap> IsMinimalNonmonomial(AlternatingGroup(5));
> Error, no method found! For debugging hints type ?Recovery from
> NoMethodFound
> Error, no 3rd choice method found for `IsMinimalNonmonomial' on 1
> arguments at /usr/share/gap/lib/methsel2.g:249 called from
>
> Is it expected ?
>
> I found this while doing:
> gap> AllGroups(Size,[1..100],IsMinimalNonmonomial,true);
> Error, no method found! For debugging hints type ?Recovery from
>
> Cheers,
> Bill.
>
> _______________________________________________
> Forum mailing list
> Forum at gap-system.org
>
> https://urldefense.com/v3/__https://mail.gap-system.org/mailman/listinfo/forum__;!!LIr3w8kk_Xxm!4HEYvPNAAX-K4jtQQlE0Q9U2zOU_jEew31HTsAPmo5BDed2H2TohyiKmpoA7mi0$
>
> _______________________________________________
> Forum mailing list
> Forum at gap-system.org
>
> https://urldefense.com/v3/__https://mail.gap-system.org/mailman/listinfo/forum__;!!LIr3w8kk_Xxm!4HEYvPNAAX-K4jtQQlE0Q9U2zOU_jEew31HTsAPmo5BDed2H2TohyiKmpoA7mi0$
>