Goto Chapter: Top 1 2 3 4 5 6 7 8 Bib Ind
 [Top of Book]  [Contents]   [Previous Chapter]   [Next Chapter] 

4 Groupoids
 4.1 Groupoids: their properties and attributes
 4.2 Groupoid elements; stars; costars; homsets
 4.3 Subgroupoids
 4.4 Left, right and double cosets
 4.5 Conjugation

4 Groupoids

A groupoid is a (mathematical) category in which every element is invertible. It consists of a set of pieces, each of which is a connected groupoid. The usual terminology is `connected component', but in GAP `component' is used for `record component', so we use the term single piece.

The simplest form for a single piece groupoid is the direct product of a group and a complete graph, and so is determined by a set of objects obs = Ω (the least of which is the root object), and a root group grp = G. Then the elements of the groupoid are arrows g : o_1 -> o_2, stored as triples [g,o1,o2], where g ∈ G and o_1,o_2 ∈ Ω. The objects will generally be chosen to be consecutive negative integers, but any suitable ordered set is acceptable, and `consecutive' is not a requirement. The root group will usually be taken to be a permutation group, but pc-groups and fp-groups are also supported.

A group may be considered as a single piece groupoid with one object.

A groupoid is a set of one or more single piece groupoids, its pieces, and is represented as IsGroupoidRep, with attribute PiecesOfGroupoid.

A groupoid is homogeneous if it has two of more isomorphic pieces, with identical groups. The special case of homogeneous, discrete groupoids, where each piece has a single object, is given its own representation. These are used in the XMod package as the source of a crossed modules of groupoids.

For the definitions of the standard properties of groupoids we refer to R. Brown's book ``Topology'' [Bro88], recently revised and reissued as ``Topology and Groupoids'' [Bro06].

4.1 Groupoids: their properties and attributes

4.1-1 SinglePieceGroupoid
‣ SinglePieceGroupoid( grp, obs )( operation )
‣ Groupoid( args )( function )
‣ DomainWithSingleObject( gp, obj )( operation )

The simplest construction of a groupoid is as the direct product of a group and a complete graph. Such a groupoid will be called a standard groupoid. Many subgroupoids of such a groupoid do not have this simple form, and will be considered in section 4.3. The global function Groupoid will normally find the appropriate constructor to call, the options being:

Methods for ViewObj, PrintObj and Display are provided for groupoids and the other types of object in this package. Users are advised to supply names for all the groups and groupoids they construct.

In the last two examples Gf2c6 and Gabc show that the objects need not be integers.


gap> s4 := Group( (1,2,3,4), (3,4) );; 
gap> d8 := Subgroup( s4, [ (1,2,3,4), (1,3) ] );;
gap> SetName( s4, "s4" );  SetName( d8, "d8" ); 
gap> Gs4 := SinglePieceGroupoid( s4, [-15 .. -11] ); 
single piece groupoid: < s4, [ -15 .. -11 ] >
gap> Gd8 := Groupoid( d8, [-9,-8,-7] );
single piece groupoid: < d8, [ -9, -8, -7 ] >
gap> c6 := Group( (5,6,7)(8,9) );;
gap> SetName( c6, "c6" );
gap> Gc6 := DomainWithSingleObject( c6, -6 );
single piece groupoid: < c6, [ -6 ] >
gap> SetName( Gs4, "Gs4" );  SetName( Gd8, "Gd8" );  SetName( Gc6, "Gc6" );  
gap> G3 := Groupoid( [ Gc6, Gd8, Gs4 ] );
groupoid with 3 pieces:
[ Gs4, Gd8, Gc6 ]
gap> f2 := FreeGroup(2);;
gap> Gf2c6 := Groupoid( c6, GeneratorsOfGroup(f2) );
single piece groupoid: < c6, [ f1, f2 ] >
gap> Gabc := Groupoid( d8, [ "a", "b", "c" ] );
single piece groupoid: < d8, [ "a", "b", "c" ] >

4.1-2 ObjectList
‣ ObjectList( gpd )( attribute )
‣ RootObject( gpd )( attribute )
‣ RootGroup( gpd )( attribute )
‣ ObjectGroup( gpd, obj )( operation )

The ObjectList of a groupoid is the sorted list of objects. The RootObject in a single-piece groupoid is the object with least label. A loop is an arrow of the form g : o -> o, and the loops at a particular object o form a group, the ObjectGroup at o. The RootGroup is the ObjectGroup at the RootObject.


gap> ObjectList( Gs4 );    
[ -15, -14, -13, -12, -11 ]
gap> RootObject( Gd8 );
-9
gap> RootGroup( Gc6 );
c6
gap> ObjectGroup( Gs4, -11 );
s4

4.1-3 IsPermGroupoid
‣ IsPermGroupoid( gpd )( property )
‣ IsPcGroupoid( gpd )( property )
‣ IsFpGroupoid( gpd )( property )
‣ IsMatrixGroupoid( gpd )( property )

A groupoid is a permutation groupoid if all its pieces have permutation groups. Most of the examples in this chapter are permutation groupoids, but in principle any type of group known to GAP may be used. In the following example Gf2 is an fp-groupoid, Gq8 is a pc-groupoid, and Gsl43 is a matrix groupoid.


gap> f2 := FreeGroup( 2 );;
gap> Gf2 := Groupoid( f2, -22 );;
gap> SetName( f2, "f2" );  SetName( Gf2, "Gf2" ); 
gap> q8 := SmallGroup( 8, 4 );;
gap> Gq8 := Groupoid( q8, [ -28, -27 ] );;
gap> SetName( q8, "q8" );  SetName( Gq8, "Gq8" );
gap> sl43 := SpecialLinearGroup( 4, 3 );;
gap> Gsl43 := SinglePieceGroupoid( sl43, [ -35..-31 ] );;
gap> SetName( sl43, "sl43" );  SetName( Gsl43, "Gsl43" );
gap> [ IsMatrixGroupoid( Gsl43 ), IsFpGroupoid( Gf2 ), 
>      IsPcGroupoid( Gq8 ), IsPermGroupoid( Gs4 ) ]; 
[ true, true, true, true ]

4.1-4 UnionOfPieces
‣ UnionOfPieces( pieces )( operation )
‣ Pieces( gpd )( attribute )
‣ Size( gpd )( attribute )
‣ ReplaceOnePieceInUnion( U, old_piece, new_piece )( operation )

When a groupoid consists of two or more pieces, we require their object lists to be disjoint. The operation UnionOfPieces and the attribute Pieces, introduced in section 2.4, are also used for groupoids. The pieces are sorted by the least object in their object lists. The ObjectList is the sorted concatenation of the objects in the pieces.

The Size of a groupoid is the number of its arrows which, for a single piece groupoid, is the product of the size of the group with the square of the number of objects.

One of the pieces in a groupoid may be replaced by an alternative piece using the operation ReplaceOnePieceInUnion. The old_piece may be either the position oif the piece to be replaced, or one of the pieces in U. The objects in the new piece may or may not overlap the objects in the piece removed -- we just require that the object lists in the new union are disjoint.


gap> U3 := UnionOfPieces( [ Gs4, Gd8, Gc6 ] );;
gap> Display( U3 );
groupoid with 3 pieces:
< objects: [ -15 .. -11 ]
    group: s4 = <[ (1,2,3,4), (3,4) ]> >
< objects: [ -9, -8, -7 ]
    group: d8 = <[ (1,2,3,4), (1,3) ]> >
< objects: [ -6 ]
    group: c6 = <[ (5,6,7)(8,9) ]> >
gap> Pieces( U3 );
[ Gs4, Gd8, Gc6 ]
gap> ObjectList( U3 );
[ -15, -14, -13, -12, -11, -9, -8, -7, -6 ]
gap> U2 := Groupoid( [ Gf2, Gq8 ] );;
gap> [ Size(Gs4), Size(Gd8), Size(Gc6), Size(U3) ];
[ 600, 72, 6, 678 ]
gap> [ Size(Gf2), Size(Gq8), Size(U2) ];           
[ infinity, 32, infinity ]
gap> U5 := UnionOfPieces( [ U3, Gf2, Gq8 ] );
groupoid with 5 pieces:
[ Gq8, Gf2, Gs4, Gd8, Gc6 ]
gap> V5 := ReplaceOnePieceInUnion( U5, 3, Gsl43 ); 
groupoid with 5 pieces:
[ Gsl43, Gq8, Gf2, Gd8, Gc6 ]
gap> ObjectList(V5);             
[ -35, -34, -33, -32, -31, -28, -27, -22, -9, -8, -7, -6 ]
gap> U5 = V5; 
false
gap> W5 := ReplaceOnePieceInUnion( V5, Gc6, Gs4 ); 
groupoid with 5 pieces:
[ Gsl43, Gq8, Gf2, Gs4, Gd8 ]

4.1-5 HomogeneousGroupoid
‣ HomogeneousGroupoid( gpd, oblist )( operation )
‣ HomogeneousDiscreteGroupoid( gp, obs )( operation )

Special functions are provided for the case where a groupoid has more than one connected component, and these components are identical except for their object sets. Such groupoids are said to be homogeneous.

The operation HomogeneousGroupoid is used when the components each contain more than one object. The arguments consist of a single piece groupoid gpd and a list of lists of objects oblist, each of whose lists has the same length as the object list obs of gpd. Note that gpd is not included as one of the pieces in the output unless obs is included as one of the lists in oblist.

The operation HomogeneousDiscreteGroupoid is used when the components each have a single object. In this case the first argument is just a group -- the root group for each component. These groupoids are used in the XMod package as the source of many crossed modules of groupoids.

Both types of groupoid have the property IsHomogeneousDomainWithObjects. In the latter case a separate representation IsHomogeneousDiscreteGroupoidRep is used.


gap> Hd8 := HomogeneousGroupoid( Gd8, [ [-12,-11,-10], [-16,-15,-14] ] ); 
homogeneous groupoid with 2 pieces:
1:  single piece groupoid: < d8, [ -16, -15, -14 ] >
2:  single piece groupoid: < d8, [ -12, -11, -10 ] >
gap> IsHomogeneousDomainWithObjects(Hd8);               
true
gap> Hc6 := HomogeneousDiscreteGroupoid( c6, [-7..-4] );
homogeneous, discrete groupoid: < c6, [ -7 .. -4 ] >
gap> RepresentationsOfObject(Gd8);
[ "IsComponentObjectRep", "IsAttributeStoringRep", "IsMWOSinglePieceRep" ]
gap> RepresentationsOfObject(Hd8);
[ "IsComponentObjectRep", "IsAttributeStoringRep", "IsPiecesRep" ]
gap> RepresentationsOfObject(Hc6);
[ "IsComponentObjectRep", "IsAttributeStoringRep", 
  "IsHomogeneousDiscreteGroupoidRep" ]
gap> KnownTruePropertiesOfObject(Hc6); 
[ "CanEasilyCompareElements", "CanEasilySortElements", "IsDuplicateFree", 
  "IsAssociative", "IsCommutative", "IsDiscreteDomainWithObjects", 
  "IsHomogeneousDomainWithObjects" ]
gap> Kd8 := UnionOfPieces( [ Gd8, Hd8 ] );
groupoid with 3 pieces:
1:  single piece groupoid: < d8, [ -16, -15, -14 ] >
2:  single piece groupoid: < d8, [ -12, -11, -10 ] >
3:  Gd8
gap> ObjectList(Kd8);
[ -16, -15, -14, -12, -11, -10, -9, -8, -7 ]
gap> IsHomogeneousDomainWithObjects( Kd8 );
true

4.2 Groupoid elements; stars; costars; homsets

4.2-1 Arrow
‣ Arrow( gpd, elt, tail, head )( operation )
‣ ElementOfArrow( elt )( operation )
‣ TailOfArrow( elt )( operation )
‣ HeadOfArrow( elt )( operation )
‣ IsArrowIn( arr, gpd )( operation )

A groupoid element is an arrow in a magma with objects, as described in subsection 2.1-2. To recapitulate, an arrow e consists of a group element, ElementOfArrow(e); the tail (source) object, TailOfArrow(e); and the head (target) object, HeadOfArrow(e). Arrows have a partial composition: two arrows may be multiplied when the head of the first coincides with the tail of the second. When an attempt is made to multiply arrows where this condition does not hold, then the value fail is returned. (In earlier versions of the package there were functions GroupoidElement and MultiplicativeElementWithObjects, but these have now been replaced by Arrow.)


gap> e1 := Arrow( Gd8, (1,2,3,4), -9, -8 );
[(1,2,3,4) : -9 -> -8]
gap> e2 := Arrow( Gd8, (1,3), -8, -7 );
[(1,3) : -8 -> -7]
gap> Print( [ ElementOfArrow(e2), TailOfArrow(e2), HeadOfArrow(e2) ], "\n" );
[ (1,3), -8, -7 ]
gap> prod := e1*e2;
[(1,2)(3,4) : -9 -> -7]
gap> e2*e1;
fail
gap> e3 := Arrow( Gd8, (2,4), -7, -9 );;
gap> loop := prod*e3;
[(1,4,3,2) : -9 -> -9]
gap> loop^2;
[(1,3)(2,4) : -9 -> -9]

4.2-2 IdentityArrow
‣ IdentityArrow( gpd, obj )( operation )

The identity arrow 1_o of G at object o is (e:o -> o) where e is the identity element in the object group. The inverse e^-1 of e = (c : p -> q) is (c^-1 : q -> p), so that e*e^-1=1_p and e^-1*e = 1_q.


gap> i8 := IdentityArrow( Gd8, -8 );
[() : -8 -> -8]
gap> [ e1*i8, i8*e1, e1^-1]; 
[ [(1,2,3,4) : -9 -> -8], fail, [(1,4,3,2) : -8 -> -9] ]

4.2-3 Order
‣ Order( arr )( attribute )

A groupoid element is a loop when the tail and head coincide. In this case the order of the element is defined to be the order of its group element.


gap> i8; Order(i8);
[() : -8 -> -8]
1
gap> loop; Order(loop);
[(1,4,3,2) : -9 -> -9]
4

4.2-4 ObjectStar
‣ ObjectStar( gpd, obj )( operation )
‣ ObjectCostar( gpd, obj )( operation )
‣ Homset( gpd, tail, head )( operation )

The star at obj is the set of arrows which have obj as tail, while the costar is the set of arrows which have obj as head. The homset from obj1 to obj2 is the set of arrows with the specified tail and head, and so is bijective with the elements of the object groups. Thus every star and every costar is a union of homsets. The identity arrow at an object is a left identity for the star and a right identity for the costar at that object.

In order not to create unneccessarily long lists, these operations return objects of type IsHomsetCosetsRep for which an Iterator is provided. (An Enumerator is not yet implemented.)


gap> star9 := ObjectStar( Gd8, -9 );
<star at [ -9 ] with group d8>
gap> Size( star9 ); 
24
gap> for e in star9 do
>      if ( Order( ElementOfArrow(e) ) = 4 ) then Print( e, "\n" ); fi;
>    od;
[(1,4,3,2) : -9 -> -9]
[(1,4,3,2) : -9 -> -8]
[(1,4,3,2) : -9 -> -7]
[(1,2,3,4) : -9 -> -9]
[(1,2,3,4) : -9 -> -8]
[(1,2,3,4) : -9 -> -7]
gap> costar6 := ObjectCostar( Gc6, -6 );
<costar at [ -6 ] with group c6>
gap> Size( costar6 ); 
6
gap> hsetq8 := Homset( Gq8, -28, -27 );
<homset -28 -> -27 with group q8>
gap> for e in hsetq8 do Print(e,"\n"); od;
[<identity> of ... : -28 -> -27]
[f3 : -28 -> -27]
[f2 : -28 -> -27]
[f2*f3 : -28 -> -27]
[f1 : -28 -> -27]
[f1*f3 : -28 -> -27]
[f1*f2 : -28 -> -27]
[f1*f2*f3 : -28 -> -27]

4.3 Subgroupoids

4.3-1 Subgroupoid
‣ Subgroupoid( args )( function )
‣ SubgroupoidByPieces( gpd, obhoms )( operation )
‣ IsSubgroupoid( gpd, sgpd )( operation )
‣ FullSubgroupoid( gpd, obs )( operation )
‣ MaximalDiscreteSubgroupoid( gpd )( attribute )
‣ DiscreteSubgroupoid( gpd, sgps, obs )( operation )
‣ FullTrivialSubgroupoid( gpd )( attribute )
‣ DiscreteTrivialSubgroupoid( gpd )( attribute )
‣ IsWide( gpd, sgpd )( operation )

A subgroupoid sgpd of a groupoid gpd has as objects some subset of the objects of gpd. It is wide if all the objects are included. It is full if, for any two objects in sgpd, the Homset is the same as that in gpd. The arrows of sgpd are a subset of those of gpd, closed under multiplication and with tail and head in the chosen object set.

There are a variety of constructors for a subgroupoid of a standard groupoid, and the most general is the operation SubgroupoidByPieces. Its two parameters are a groupoid and a list of pieces, each piece being specified as a list [sgp,obs], where sgp is a subgroup of the root group in that piece, and obs is a subset of the objects in that piece. The FullSubgroupoid of a groupoid gpd on a subset obs of its objects contains all the arrows of gpd with tail and head in obs. A subgroupoid is discrete if it is a union of groups. The MaximalDiscreteSubgroupoid of gpd is the union of all the single-object full subgroupoids of gpd. A trivial subgroupoid has trivial object groups, but need not be discrete. A single piece trivial groupoid is sometimes called a tree groupoid. (The term identity subgroupoid was used in versions up to 1.14.) The global function Subgroupoid should call the appropriate operation.


gap> c4 := Subgroup( d8, [ (1,2,3,4) ] );;
gap> k4 := Subgroup( d8, [ (1,2)(3,4), (1,3)(2,4) ] );;
gap> SetName( c4, "c4" );  SetName( k4, "k4" );
gap> Ud8 := Subgroupoid( Gd8, [ [ k4, [-9] ], [ c4, [-8,-7] ] ] );;
gap> SetName( Ud8, "Ud8" );
gap> Display( Ud8 );
groupoid with 2 pieces:
< objects: [ -9 ]
    group: k4 = <[ (1,2)(3,4), (1,3)(2,4) ]> >
< objects: [ -8, -7 ]
    group: c4 = <[ (1,2,3,4) ]> >
gap> [ Parent( Ud8 ), IsWide( Gd8, Ud8 ) ]; 
[ Gd8, true ]
gap> genf2b := List( GeneratorsOfGroup(f2), g -> g^2 );
[ f1^2, f2^2 ]
gap> f2b := Subgroup( f2, genf2b );;
gap> SubgroupoidByPieces( U2, [ [q8,[-27]], [f2b,[-22]] ] );
groupoid with 2 pieces:
1:  single piece groupoid: < q8, [ -27 ] >
2:  single piece groupoid: < Group( [ f1^2, f2^2 ] ), [ -22 ] >
gap> IsSubgroupoid( Gf2, Groupoid( f2b, [-22] ) );
true
gap> FullSubgroupoid( U3, [-7,-6] );
groupoid with 2 pieces:
1:  single piece groupoid: < d8, [ -7 ] >
2:  single piece groupoid: < c6, [ -6 ] >
gap> DiscreteSubgroupoid( U3, [ c4, k4 ], [-9,-7] );
groupoid with 2 pieces:
1:  single piece groupoid: < c4, [ -9 ] >
2:  single piece groupoid: < k4, [ -7 ] >
gap> FullTrivialSubgroupoid( Ud8 );
groupoid with 2 pieces:
1:  single piece groupoid: < id(k4), [ -9 ] >
2:  single piece groupoid: < id(c4), [ -8, -7 ] >
gap> MaximalDiscreteSubgroupoid(U2);
groupoid with 3 pieces:
1:  single piece groupoid: < q8, [ -28 ] >
2:  single piece groupoid: < q8, [ -27 ] >
3:  single piece groupoid: < f2, [ -22 ] >

4.3-2 SubgroupoidWithRays
‣ SubgroupoidWithRays( gpd, sgp, rays )( operation )
‣ RaysOfGroupoid( gpd )( operation )
‣ RayElementsOfGroupoid( gpd )( operation )

If groupoid G is of type IsDirectProductWithCompleteGraph with group g and n objects, then a typical wide subgroupoid H of G is formed by choosing a subgroup h of g to be the object group at the root object q, and an arrow r : q -> p for each of the objects p. The chosen loop arrow at q must be the identity arrow. These n arrows are called the rays of the subgroupoid. The arrows in the homset from p to p' have the form r^-1xr' where r,r' are the rays from q to p,p' respectively, and x ∈ h.

The operation RaysOfGroupoid returns a list of arrows, one for each object, while the operation RayElementsOfGroupoid returns the list of group elements in these arrows.

In the following example we construct a subgroupoid with rays on three of the five objects. It is therefore necessary to construct the full subgroupoid on these three objects first.

Note that it is also possible to construct a subgroupoid with rays of a subgroupoid with rays.

Note also that the function Ancestor provides an iteration of Parent.


gap> Hs4 := FullSubgroupoid( Gs4, [-14,-13,-12] );; 
gap> SetName( Hs4, "Hs4" ); 
gap> Hd8a := SubgroupoidWithRays( Hs4, d8, [(),(2,3),(3,4)] );
single piece groupoid with rays: < d8, [ -14, -13, -12 ], [ (), (2,3), (3,4)
 ] >
gap> hs1413 := Homset( Hd8a, -14, -13 );
<homset -14 -> -13 with group d8>
gap> for e in hs1413 do  Print(e,", "); od;  Print( "\n");
[(2,3) : -14 -> -13], [(1,2,4,3) : -14 -> -13], [(1,4,2) : -14 -> -13], [
(1,3,4) : -14 -> -13], [(2,4,3) : -14 -> -13], [(1,2,3) : -14 -> -13], [
(1,4) : -14 -> -13], [(1,3,4,2) : -14 -> -13], 
gap> Hd8b := SubgroupoidWithRays( Hs4, d8, [(),(1,2,3),(1,2,4)] );
single piece groupoid with rays: < d8, [ -14, -13, -12 ],
[ (), (1,2,3), (1,2,4) ] >
gap> Hd8a = Hd8b; 
true
gap> RaysOfGroupoid( Hd8b );
[ [() : -14 -> -14], [(1,2,3) : -14 -> -13], [(1,2,4) : -14 -> -12] ]
gap> RayElementsOfGroupoid( Hd8b ); 
[ (), (1,2,3), (1,2,4) ]
gap> Parent( Hd8a );
Hs4
gap> Ancestor( Hd8a ); 
Gs4
gap> Fd8a := FullSubgroupoid( Hd8a, [-14,-13]);
single piece groupoid with rays: < d8, [ -14, -13 ], [ (), (2,3) ] >
gap> Fd8b := FullSubgroupoid( Hd8a, [-13,-12]);
single piece groupoid with rays: < Group( [ (1,3,2,4), (1,2) ] ), 
[ -13, -12 ], [ (), (2,4,3) ] >
gap> Fd8a := FullSubgroupoid( Hd8a, [-13,-12] );            
single piece groupoid with rays: < Group( [ (1,3,2,4), (1,2) ] ), 
[ -13, -12 ], [ (), (2,4,3) ] >
gap> Kd8a := SubgroupoidWithRays( Fd8a, k4, [ (), (1,3) ] ); 
single piece groupoid with rays: < k4, [ -13, -12 ], [ (), (1,3) ] >

4.4 Left, right and double cosets

4.4-1 RightCoset
‣ RightCoset( G, U, elt )( operation )
‣ RightCosetRepresentatives( G, U )( operation )
‣ LeftCoset( G, U, elt )( operation )
‣ LeftCosetRepresentatives( G, U )( operation )
‣ LeftCosetRepresentativesFromObject( G, U, obj )( operation )
‣ DoubleCoset( G, U, elt, V )( operation )
‣ DoubleCosetRepresentatives( G, U, V )( operation )

If U is a wide subgroupoid of G, the right cosets Ug of U in G are the equivalence classes for the relation on the arrows of G where g1 is related to g2 if and only if g2 = u*g1 for some arrow u of U. The right coset containing g is written Ug. These right cosets partition the costars of G and, in particular, the costar U1_o of U at object o, so that (unlike groups) U is itself a coset only when G has a single object.

The right coset representatives for U in G form a list containing one arrow for each coset where, in a particular piece of U, the group element chosen is the right coset representative of the group of U in the group of G.

Similarly, the left cosets gU refine the stars of G, while double cosets are unions of left cosets and right cosets. The operation LeftCosetRepresentativesFromObject( G, U, obj ) is used in Chapter 4, and returns only those representatives which have tail at obj.

As with stars and homsets, these cosets are implemented with representation IsHomsetCosetsRep and provided with an iterator. Note that, when U has more than one piece, cosets may have differing lengths.


gap> re2 := RightCoset( Gd8, Ud8, e2 );
RightCoset(single piece groupoid: < c4, [ -8, -7 ] >,[(1,3) : -8 -> -7])
gap> for x in re2 do Print( x, "\n" ); od;
[(1,3) : -8 -> -7]
[(1,3) : -7 -> -7]
[(2,4) : -8 -> -7]
[(2,4) : -7 -> -7]
[(1,4)(2,3) : -8 -> -7]
[(1,4)(2,3) : -7 -> -7]
[(1,2)(3,4) : -8 -> -7]
[(1,2)(3,4) : -7 -> -7]
gap> rcrd8 := RightCosetRepresentatives( Gd8, Ud8 );
[ [() : -9 -> -9], [() : -9 -> -8], [() : -9 -> -7], [(2,4) : -9 -> -9],
  [(2,4) : -9 -> -8], [(2,4) : -9 -> -7], [() : -8 -> -9], [() : -8 -> -8],
  [() : -8 -> -7], [(2,4) : -8 -> -9], [(2,4) : -8 -> -8], [(2,4) : -8 -> -7]
 ]
gap> lcr7 := LeftCosetRepresentativesFromObject( Gd8, Ud8, -7 );
[ [() : -7 -> -9], [(2,4) : -7 -> -9], [() : -7 -> -8], [(2,4) : -7 -> -8] ]

4.5 Conjugation

4.5-1 ConjugateArrow
‣ ConjugateArrow( e1, e )( operation )

When e = (c : p -> q) conjugation by e is the groupoid automorphism defined as follows. There are two cases.

In the case p ≠ q,

In the case p=q,

The details of this construction may be found in [AW10].

(Note that it is more desirable to use the command e1^e2, but it has not yet been possible to get this to work!)


gap> x := Arrow( Gd8, (1,3), -9, -9 );; 
gap> y := Arrow( Gd8, (1,2,3,4), -8, -9 );; 
gap> z := Arrow( Gd8, (1,2)(3,4), -9, -7 );; 
gap> w := Arrow( Gd8, (1,2,3,4), -7, -8 );; 
gap> ##  conjugation with arrows x, y, z and w in Gd8: 
gap> ConjugateArrow(x,y);
[(2,4) : -8 -> -8]
gap> ConjugateArrow(x,z);
[(2,4) : -7 -> -7]
gap> ConjugateArrow(x,w);
[(1,3) : -9 -> -9]
gap> ConjugateArrow(y,x);
[() : -8 -> -9]
gap> ConjugateArrow(y,z);
[(2,4) : -8 -> -7]
gap> ConjugateArrow(y,w);    
[(1,3)(2,4) : -7 -> -9]
gap> ConjugateArrow(z,x);
[(1,4,3,2) : -9 -> -7]
gap> ConjugateArrow(z,y);
[(2,4) : -8 -> -7]
gap> ConjugateArrow(z,w);
[(1,3) : -9 -> -8]
gap> ConjugateArrow(w,x); 
[(1,2,3,4) : -7 -> -8]
gap> ConjugateArrow(w,y);
[(1,3)(2,4) : -7 -> -9]
gap> ConjugateArrow(w,z);
[(1,3) : -9 -> -8]

4.5-2 SinglePieceSubgroupoidByGenerators
‣ SinglePieceSubgroupoidByGenerators( parent, gens )( operation )

A set of arrows generates a groupoid by taking all possible products and inverses. So far, the only implementation is for the case of loops generating a group at an object o andf a set of rays from o, where o is not the least object. A suitably large supergroupoid, which must be a direct product with a complete graph, should be provided. This is the case needed for ConjugateGroupoid in the following section. Other cases will be added as time permits.


gap> u := Arrow( Gs4, (1,2,3), -15, -13 ); 
[(1,2,3) : -15 -> -13]
gap> gensa := GeneratorsOfGroupoid( Hd8a );
[ [(1,2,3,4) : -14 -> -14], [(1,3) : -14 -> -14], [(2,3) : -14 -> -13], 
  [(3,4) : -14 -> -12] ]
gap> imsa := List( gensa, g -> ConjugateArrow( g, u ) ); 
[ [(1,2,3,4) : -14 -> -14], [(1,3) : -14 -> -14], [(1,3) : -14 -> -15], 
  [(3,4) : -14 -> -12] ]
gap> C := SinglePieceSubgroupoidByGenerators( Gs4, imsa ); 
single piece groupoid with rays: < Group( [ (1,4,3,2), (1,3) ] ), 
[ -15, -14, -12 ], [ (), (1,3), (1,4,3) ] >

4.5-3 ConjugateGroupoid
‣ ConjugateGroupoid( gpd, e )( operation )

When H is a subgroupoid of a groupoid G and a is an arrow of G, then the conjugate of H by a is the subgroupoid generated by the conjugates of the generators of H.


gap> ConjugateGroupoid( Hd8a, u^-1 ); 
single piece groupoid with rays: < Group( [ (1,4,3,2), (1,3) ] ), 
[ -15, -14, -12 ], [ (), (1,3), (1,4,3) ] >

More examples of all these operations may be found in the example file groupoids/examples/gpd.g.

 [Top of Book]  [Contents]   [Previous Chapter]   [Next Chapter] 
Goto Chapter: Top 1 2 3 4 5 6 7 8 Bib Ind

generated by GAPDoc2HTML